Warning, /frameworks/kdoctools/cmake/FindDocBookXSL.cmake is written in an unsupported language. File is not indexed.

0001 # Try to find DocBook XSL stylesheet
0002 # Once done, it will define:
0003 #
0004 #  DocBookXSL_FOUND - system has the required DocBook XML DTDs
0005 #  DocBookXSL_DIR - the directory containing the stylesheets
0006 #  used to process DocBook XML
0007 
0008 # SPDX-FileCopyrightText: 2010 Luigi Toscano <luigi.toscano@tiscali.it>
0009 #
0010 # SPDX-License-Identifier: BSD-3-Clause
0011 
0012 include(FeatureSummary)
0013 set_package_properties(DocBookXSL PROPERTIES DESCRIPTION "DocBook XSL"
0014                        URL "http://docbook.sourceforge.net/release/xsl/current/"
0015                       )
0016 
0017 set (STYLESHEET_PATH_LIST
0018     ${CMAKE_INSTALL_DATAROOTDIR}/xml/docbook/stylesheet/docbook-xsl
0019     ${CMAKE_INSTALL_DATAROOTDIR}/xml/docbook/xsl-stylesheets
0020     ${CMAKE_INSTALL_DATAROOTDIR}/sgml/docbook/xsl-stylesheets
0021     ${CMAKE_INSTALL_DATAROOTDIR}/xml/docbook/stylesheet/nwalsh/current
0022     ${CMAKE_INSTALL_DATAROOTDIR}/xml/docbook/stylesheet/nwalsh
0023     ${CMAKE_INSTALL_DATAROOTDIR}/xsl/docbook
0024     ${CMAKE_INSTALL_DATAROOTDIR}/xsl/docbook-xsl
0025     # for building on Mac with docbook-xsl installed by homebrew
0026     opt/docbook-xsl/docbook-xsl
0027     # for building with Nix package manager
0028     xml/xsl/docbook
0029 )
0030 
0031 find_path (DocBookXSL_DIR lib/lib.xsl
0032     PATHS ${CMAKE_SYSTEM_PREFIX_PATH}
0033     PATH_SUFFIXES ${STYLESHEET_PATH_LIST}
0034 )
0035 
0036 if (NOT DocBookXSL_DIR)
0037     # hacks for systems that put the version in the stylesheet dirs
0038     set (STYLESHEET_PATH_LIST)
0039     foreach (STYLESHEET_PREFIX_ITER ${CMAKE_SYSTEM_PREFIX_PATH})
0040         file(GLOB STYLESHEET_SUFFIX_ITER RELATIVE ${STYLESHEET_PREFIX_ITER}
0041             ${STYLESHEET_PREFIX_ITER}/share/xml/docbook/xsl-stylesheets-*
0042         )
0043         if (STYLESHEET_SUFFIX_ITER)
0044             list (APPEND STYLESHEET_PATH_LIST ${STYLESHEET_SUFFIX_ITER})
0045         endif ()
0046     endforeach ()
0047 
0048     find_path (DocBookXSL_DIR VERSION
0049         PATHS ${CMAKE_SYSTEM_PREFIX_PATH}
0050         PATH_SUFFIXES ${STYLESHEET_PATH_LIST}
0051     )
0052 endif ()
0053 
0054 
0055 include(FindPackageHandleStandardArgs)
0056 find_package_handle_standard_args (DocBookXSL
0057     REQUIRED_VARS DocBookXSL_DIR
0058     FOUND_VAR DocBookXSL_FOUND)
0059 
0060 #maintain backwards compatibility
0061 set(DOCBOOKXSL_FOUND ${DocBookXSL_FOUND})
0062 set(DOCBOOKXSL_DIR ${DocBookXSL_DIR})
0063 
0064 mark_as_advanced (DocBookXSL_DIR)