Warning, /frameworks/kdnssd/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KDNSSD VERSION ${KF_VERSION})
0005 
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010 
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake/modules) #TODO: remove cmake/modules when extra-cmake-modules is done
0012 
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 
0017 include(KDEGitCommitHooks)
0018 include(ECMPoQmTools)
0019 include(ECMAddQch)
0020 include(ECMGenerateExportHeader)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMDeprecationSettings)
0024 include(CMakePackageConfigHelpers)
0025 
0026 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0027 
0028 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0029 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0030 
0031 set(REQUIRED_QT_VERSION 5.15.2)
0032 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Network)
0033 
0034 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0035 
0036 ecm_setup_version(PROJECT VARIABLE_PREFIX KDNSSD
0037     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdnssd_version.h"
0038     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5DNSSDConfigVersion.cmake"
0039     SOVERSION 5)
0040 install(FILES
0041     ${CMAKE_CURRENT_BINARY_DIR}/kdnssd_version.h
0042     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDNSSD
0043     COMPONENT Devel
0044 )
0045 
0046 configure_file(config-kdnssd.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kdnssd.h )
0047 
0048 
0049 find_package(Avahi)
0050 set_package_properties(Avahi PROPERTIES DESCRIPTION "Facilities for service discovery on a local network (DNSSD)"
0051                        URL "https://avahi.org"
0052                        TYPE OPTIONAL
0053                        PURPOSE "Either Avahi or DNSSD is required for KDE applications to make use of multicast DNS/DNS-SD service discovery"
0054                       )
0055 
0056 if(NOT AVAHI_FOUND)
0057     find_package(DNSSD)
0058     set_package_properties(DNSSD PROPERTIES DESCRIPTION "Facilities for service discovery on a local network"
0059                           URL "https://avahi.org"
0060                           TYPE OPTIONAL
0061                           PURPOSE "Either Avahi or DNSSD is required for KDE applications to make use of multicast DNS/DNS-SD service discovery"
0062                           )
0063 endif( )
0064 
0065 if(AVAHI_FOUND OR DNSSD_FOUND)
0066     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0067 endif()
0068 
0069 ecm_install_po_files_as_qm(poqm)
0070 
0071 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0072 ecm_set_disabled_deprecation_versions(
0073     QT 5.15.2
0074 )
0075 
0076 add_subdirectory(src)
0077 
0078 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5DNSSD")
0079 
0080 if (BUILD_QCH)
0081     ecm_install_qch_export(
0082         TARGETS KF5DNSSD_QCH
0083         FILE KF5DNSSDQchTargets.cmake
0084         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0085         COMPONENT Devel
0086     )
0087     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5DNSSDQchTargets.cmake\")")
0088 endif()
0089 
0090 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5DNSSDConfig.cmake.in"
0091                               "${CMAKE_CURRENT_BINARY_DIR}/KF5DNSSDConfig.cmake"
0092                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0093                               )
0094 
0095 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5DNSSDConfig.cmake"
0096                "${CMAKE_CURRENT_BINARY_DIR}/KF5DNSSDConfigVersion.cmake"
0097         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0098         COMPONENT Devel )
0099 
0100 install(EXPORT KF5DNSSDTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101         FILE KF5DNSSDTargets.cmake NAMESPACE KF5:: COMPONENT Devel)
0102 
0103 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0104 
0105 
0106 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)