frameworks/kdelibs4support/KF5KDELibs4SupportConfig.cmake.in

0001 @PACKAGE_INIT@
0002
0003 # This needs to be set before finding dependencies, since it uses
0004 # PACKAGE_PREFIX_DIR, which may be overwritten by the config files
0005 # of other packages.
0006 set(KDE4_DBUS_INTERFACES_DIR "@PACKAGE_KDE_INSTALL_DBUSINTERFACEDIR@")
0007
0008 include(CMakeFindDependencyMacro)
0009 find_dependency(KF5Auth "@KF_DEP_VERSION@")
0010 find_dependency(KF5Archive "@KF_DEP_VERSION@")
0011 find_dependency(KF5ConfigWidgets "@KF_DEP_VERSION@")
0012 find_dependency(KF5CoreAddons "@KF_DEP_VERSION@")
0013 find_dependency(KF5Crash "@KF_DEP_VERSION@")
0014 find_dependency(KF5DesignerPlugin "@KF_DEP_VERSION@")
0015 find_dependency(KF5DocTools "@KF_DEP_VERSION@")
0016 find_dependency(KF5Emoticons "@KF_DEP_VERSION@")
0017 find_dependency(KF5GuiAddons "@KF_DEP_VERSION@")
0018 find_dependency(KF5IconThemes "@KF_DEP_VERSION@")
0019 find_dependency(KF5ItemModels "@KF_DEP_VERSION@")
0020 find_dependency(KF5Init "@KF_DEP_VERSION@")
0021 find_dependency(KF5Notifications "@KF_DEP_VERSION@")
0022 find_dependency(KF5Parts "@KF_DEP_VERSION@")
0023 find_dependency(KF5TextWidgets "@KF_DEP_VERSION@")
0024 find_dependency(KF5UnitConversion "@KF_DEP_VERSION@")
0025 find_dependency(KF5WindowSystem "@KF_DEP_VERSION@")
0026 find_dependency(KF5DBusAddons "@KF_DEP_VERSION@")
0027
0028 find_dependency(Qt5DBus @REQUIRED_QT_VERSION@)
0029 find_dependency(Qt5Xml @REQUIRED_QT_VERSION@)
0030 find_dependency(Qt5PrintSupport @REQUIRED_QT_VERSION@)
0031
0032 if(WIN32)
0033     find_dependency(KDEWin)
0034 endif()
0035
0036 include("${CMAKE_CURRENT_LIST_DIR}/KF5KDELibs4SupportTargets.cmake")
0037
0038 include("${CMAKE_CURRENT_LIST_DIR}/ECMQt4To5Porting.cmake")
0039 include("${CMAKE_CURRENT_LIST_DIR}/KDE4Macros.cmake")
0040
0041 include("${CMAKE_CURRENT_LIST_DIR}/MacroAppendIf.cmake")
0042 include("${CMAKE_CURRENT_LIST_DIR}/MacroEnsureOutOfSourceBuild.cmake")
0043 include("${CMAKE_CURRENT_LIST_DIR}/MacroBoolTo01.cmake")
0044
0045 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
0046
0047 remove_definitions(
0048   -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0049   -DQT_NO_CAST_FROM_ASCII
0050   -DQT_NO_CAST_TO_ASCII
0051 )
0052
0053 # This is not intended to be a list of what frameworks each of the kde libraries
0054 # was broken into. KDE4_KDECORE_LIBS contains more than what used to be in
0055 # the kdecore library. That is a feature. These things should be big ugly warts
0056 # in any project using them. The KDELibs4Support module is not for long term use and
0057 # it is not for 'making code build with both Qt/KDE 4 and Qt/KF 5' for medium or
0058 # long term. In trivial cases, no use of KDELibs4Support will be pushed to the repo
0059 # of the code being ported.
0060 #
0061 # The use-sequence is this:
0062 # 1. When starting to port something to KF5, find and use KDELibs4Support.
0063 # 2. Port the C++ code to Qt5/KF5.
0064 # 3. Port the buildsystem away from KDELibs4Support.
0065 # 4. Remove the find_package for KDELibs4Support.
0066
0067 set(KDE4_KDECORE_LIBS
0068   KF5::KDELibs4Support
0069   Qt5::Network
0070   Qt5::DBus
0071   Qt5::Xml
0072   KF5::KIOCore
0073   KF5::I18n
0074   KF5::CoreAddons
0075   KF5::Codecs
0076   KF5::ConfigCore
0077   KF5::WidgetsAddons
0078   KF5::ItemModels
0079   KF5::ConfigWidgets
0080   KF5::Completion
0081   KF5::XmlGui
0082   KF5::IconThemes
0083   KF5::KIOWidgets
0084   KF5::ItemViews
0085   KF5::Emoticons
0086 )
0087 set(KDE4_KDEUI_LIBS  ${KDE4_KDECORE_LIBS})
0088 set(KDE4_KIO_LIBS ${KDE4_KDECORE_LIBS})
0089 set(KDE4_KPARTS_LIBS ${KDE4_KPARTS_LIBS})
0090 set(KDE4_KUTILS_LIBS ${KDE4_KUTILS_LIBS})
0091 set(KDE4_KFILE_LIBS ${KDE4_KFILE_LIBS})
0092 set(KDE4_KHTML_LIBS ${KDE4_KHTML_LIBS})
0093 set(KDE4_KDELIBS4SUPPORT_LIBS  ${KDE4_KDECORE_LIBS})
0094
0095 set(KDE4_INCLUDES $<TARGET_PROPERTY:KF5::KDELibs4Support,INTERFACE_INCLUDE_DIRECTORIES>)
0096 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC" OR (WIN32 AND CMAKE_CXX_COMPILER_ID STREQUAL "Intel"))
0097   set (KDE4_ENABLE_EXCEPTIONS -EHsc)
0098 elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
0099   set (KDE4_ENABLE_EXCEPTIONS "-fexceptions -UQT_NO_EXCEPTIONS")
0100 elseif (CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
0101   set (KDE4_ENABLE_EXCEPTIONS -fexceptions)
0102 endif()