Warning, /frameworks/kded/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KDED VERSION ${KF_VERSION})
0006 
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011 
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013 
0014 set(REQUIRED_QT_VERSION 6.5.0)
0015 
0016 include(KDEInstallDirs)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018 include(KDECMakeSettings)
0019 include(KDEGitCommitHooks)
0020 include(ECMDeprecationSettings)
0021 
0022 find_package(Qt6 "${REQUIRED_QT_VERSION}" CONFIG REQUIRED DBus Widgets)
0023 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0024 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0025 find_package(KF6Crash ${KF_DEP_VERSION} REQUIRED)
0026 find_package(KF6DBusAddons ${KF_DEP_VERSION} REQUIRED)
0027 find_package(KF6DocTools ${KF_DEP_VERSION})
0028 find_package(KF6Service ${KF_DEP_VERSION} REQUIRED)
0029 
0030 
0031 include(CMakePackageConfigHelpers)
0032 include(ECMQtDeclareLoggingCategory)
0033 include(ECMSetupVersion)
0034 include(ECMMarkNonGuiExecutable)
0035 
0036 ecm_setup_version(
0037   PROJECT
0038   VARIABLE_PREFIX KDED
0039   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kded_version.h"
0040   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6KDEDConfigVersion.cmake"
0041   SOVERSION 6)
0042 
0043 # We don't install kded_version.h, it's only useful internally
0044 # (given that this framework produces no library)
0045 
0046 ecm_set_disabled_deprecation_versions(
0047     QT 6.5
0048     KF 5.240.0
0049 )
0050 
0051 if (KF6DocTools_FOUND)
0052     kdoctools_install(po)
0053     add_subdirectory(docs)
0054 endif()
0055 
0056 add_subdirectory(src)
0057 
0058 # Create a Config.cmake and a ConfigVersion.cmake file and install them
0059 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6KDED")
0060 
0061 configure_package_config_file(
0062   "${CMAKE_CURRENT_SOURCE_DIR}/KF6KDEDConfig.cmake.in"
0063   "${CMAKE_CURRENT_BINARY_DIR}/KF6KDEDConfig.cmake"
0064   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0065   INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0066 )
0067 
0068 install(FILES
0069   "${CMAKE_CURRENT_BINARY_DIR}/KF6KDEDConfig.cmake"
0070   "${CMAKE_CURRENT_BINARY_DIR}/KF6KDEDConfigVersion.cmake"
0071   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072   COMPONENT Devel
0073 )
0074 
0075 install(FILES org.kde.kded6.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0076 
0077 ecm_qt_install_logging_categories(
0078         EXPORT KDED
0079         FILE kded.categories
0080         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0081         )
0082 
0083 include(ECMFeatureSummary)
0084 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0085 
0086 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)