src/quickaddons/CMakeLists.txt

0001 set(KF5QuickAddons_LIB_SRCS
0002     configmodule.cpp
0003     configmodule.h
0004     imagetexturescache.cpp
0005     imagetexturescache.h
0006     managedconfigmodule.cpp
0007     managedconfigmodule.h
0008     managedtexturenode.cpp
0009     managedtexturenode.h
0010     qtquicksettings.cpp
0011     qtquicksettings.h
0012     quickviewsharedengine.cpp
0013     quickviewsharedengine.h)
0014 kconfig_add_kcfg_files(KF5QuickAddons_LIB_SRCS renderersettings.kcfgc)
0015
0016 add_library(KF5QuickAddons ${KF5QuickAddons_LIB_SRCS})
0017
0018 ecm_generate_export_header(KF5QuickAddons
0019     EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/quickaddons_export.h
0020     BASE_NAME QuickAddons
0021     GROUP_BASE_NAME KF
0022     VERSION ${KF_VERSION}
0023     DEPRECATED_BASE_VERSION 0
0024     DEPRECATION_VERSIONS 5.88 5.93 5.104
0025     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0026 )
0027
0028 add_library(KF5::QuickAddons ALIAS KF5QuickAddons)
0029
0030 # Apps must include <KQuickAddons/File> or <kquickaddons/file.h>
0031 target_include_directories(KF5QuickAddons INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative>"
0032                                           PUBLIC "$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}>" # for kdeclarative/kdeclarative_export.h
0033 )
0034
0035 target_link_libraries(KF5QuickAddons
0036   PUBLIC
0037     Qt${QT_MAJOR_VERSION}::Quick
0038     KF5::CoreAddons
0039   PRIVATE
0040     KF5::I18n
0041     KF5::Declarative
0042     KF5::ConfigGui
0043 )
0044 if (ANDROID)
0045     target_link_libraries(KF5QuickAddons PRIVATE GLESv3)
0046 endif()
0047
0048 set_target_properties(KF5QuickAddons
0049   PROPERTIES VERSION ${KDECLARATIVE_VERSION}
0050   SOVERSION ${KDECLARATIVE_SOVERSION}
0051   EXPORT_NAME QuickAddons
0052 )
0053
0054 # Install files
0055 #those are deprecated, offered just for compatibility
0056 ecm_generate_headers(QuickAddons_CamelCase_HEADERS
0057   HEADER_NAMES
0058   ImageTexturesCache
0059   ManagedTextureNode
0060   PREFIX QuickAddons
0061   REQUIRED_HEADERS QuickAddons_HEADERS
0062 )
0063 install(FILES ${QuickAddons_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/QuickAddons COMPONENT Devel)
0064
0065 # Install files
0066 ecm_generate_headers(KQuickAddons_CamelCase_HEADERS
0067   HEADER_NAMES
0068   ImageTexturesCache
0069   ManagedTextureNode
0070   QtQuickSettings
0071   ConfigModule
0072   ManagedConfigModule
0073   QuickViewSharedEngine
0074
0075   PREFIX KQuickAddons
0076   REQUIRED_HEADERS KQuickAddons_HEADERS
0077 )
0078 install(FILES ${KQuickAddons_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/KQuickAddons COMPONENT Devel)
0079
0080 install(TARGETS KF5QuickAddons
0081   EXPORT KF5DeclarativeTargets
0082   ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0083 )
0084
0085 install(FILES
0086   ${CMAKE_CURRENT_BINARY_DIR}/quickaddons_export.h
0087   ${QuickAddons_HEADERS}
0088   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/quickaddons
0089   COMPONENT Devel
0090 )
0091
0092 install(FILES
0093   ${CMAKE_CURRENT_BINARY_DIR}/quickaddons_export.h
0094   ${KQuickAddons_HEADERS}
0095   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/kquickaddons
0096   COMPONENT Devel
0097 )
0098
0099 # make available to ecm_add_qch in parent folder
0100 set(KQuickAddons_QCH_SOURCES ${KQuickAddons_HEADERS} PARENT_SCOPE)
0101 set(KQuickAddons_QCH_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR} PARENT_SCOPE)
0102
0103 include(ECMGeneratePriFile)
0104 ecm_generate_pri_file(BASE_NAME QuickAddons LIB_NAME KF5QuickAddons DEPS "qml" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/QuickAddons)
0105 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})