src/calendarevents/CMakeLists.txt

0001 set(calendar-integration_SRCS
0002     calendareventsplugin.cpp
0003     calendareventsplugin.h
0004     eventdata_p.cpp
0005 )
0006
0007 add_library(KF5CalendarEvents ${calendar-integration_SRCS})
0008 add_library(KF5::CalendarEvents ALIAS KF5CalendarEvents)
0009
0010 ecm_generate_export_header(KF5CalendarEvents
0011     BASE_NAME CalendarEvents
0012     GROUP_BASE_NAME KF
0013     VERSION ${KF_VERSION}
0014     DEPRECATED_BASE_VERSION 0
0015     DEPRECATION_VERSIONS 5.106
0016     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0017 )
0018
0019 target_link_libraries(KF5CalendarEvents PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0020
0021 target_include_directories(KF5CalendarEvents INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative>")
0022 set_target_properties(KF5CalendarEvents PROPERTIES VERSION ${KDECLARATIVE_VERSION}
0023                                                 SOVERSION ${KDECLARATIVE_SOVERSION}
0024                                                 EXPORT_NAME CalendarEvents
0025 )
0026
0027 install(TARGETS KF5CalendarEvents EXPORT KF5DeclarativeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0028
0029 ecm_generate_headers(CalendarEvents_CamelCase_HEADERS
0030   HEADER_NAMES
0031   CalendarEventsPlugin
0032
0033   PREFIX CalendarEvents
0034   REQUIRED_HEADERS CalendarEvents_HEADERS
0035 )
0036 install(FILES ${CalendarEvents_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/CalendarEvents COMPONENT Devel)
0037
0038 install (FILES
0039         ${CalendarEvents_HEADERS}
0040         ${CMAKE_CURRENT_BINARY_DIR}/calendarevents_export.h
0041         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative/calendarevents COMPONENT Devel
0042 )
0043
0044 # make available to ecm_add_qch in parent folder
0045 set(CalendarEvents_QCH_SOURCES ${CalendarEvents_HEADERS} PARENT_SCOPE)
0046 set(CalendarEvents_QCH_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR} PARENT_SCOPE)