frameworks/kdeclarative/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 set(REQUIRED_QT_VERSION 6.5.0)
0006 project(KDeclarative VERSION ${KF_VERSION})
0007
0008 # Dependencies
0009 include(FeatureSummary)
0010 find_package(ECM 5.249.0  NO_MODULE)
0011 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0012 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0013
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0015
0016 include(KDEInstallDirs)
0017 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0018 include(KDECMakeSettings)
0019 include(KDEGitCommitHooks)
0020 include(ECMDeprecationSettings)
0021 include(ECMGenerateExportHeader)
0022 include(ECMSetupVersion)
0023 include(ECMGenerateHeaders)
0024 include(ECMQmlModule)
0025 include(CMakePackageConfigHelpers)
0026 include(ECMAddQch)
0027
0028 find_package(Qt6 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Qml Quick Gui)
0029 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0030 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0031 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0032 find_package(KF6GuiAddons ${KF_DEP_VERSION} REQUIRED)
0033
0034
0035 if(NOT WIN32 AND NOT APPLE)
0036     find_package(KF6GlobalAccel ${KF_DEP_VERSION} REQUIRED)
0037 endif()
0038
0039 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0040
0041 option(BUILD_EXAMPLES "Build and install examples." OFF)
0042 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0043 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0044
0045
0046 # ECM setup
0047 ecm_setup_version(
0048   PROJECT
0049   VARIABLE_PREFIX KDECLARATIVE
0050   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdeclarative_version.h"
0051   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6DeclarativeConfigVersion.cmake"
0052   SOVERSION 6)
0053
0054 # Subdirectories
0055 add_definitions(-DTRANSLATION_DOMAIN=\"kdeclarative6\")
0056 ecm_set_disabled_deprecation_versions(
0057     QT 6.5.0
0058     KF 5.102
0059 )
0060
0061 ki18n_install(po)
0062
0063 add_subdirectory(src)
0064 if (BUILD_TESTING)
0065     add_subdirectory(tests)
0066 endif()
0067
0068 # Create a Config.cmake and a ConfigVersion.cmake file and install them
0069 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Declarative")
0070
0071 if (BUILD_QCH)
0072     ecm_install_qch_export(
0073         TARGETS KF6Declarative_QCH
0074         FILE KF6DeclarativeQchTargets.cmake
0075         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0076         COMPONENT Devel
0077     )
0078     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6DeclarativeQchTargets.cmake\")")
0079 endif()
0080
0081 configure_package_config_file(
0082   "${CMAKE_CURRENT_SOURCE_DIR}/KF6DeclarativeConfig.cmake.in"
0083   "${CMAKE_CURRENT_BINARY_DIR}/KF6DeclarativeConfig.cmake"
0084   INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0085 )
0086
0087 install(FILES
0088   "${CMAKE_CURRENT_BINARY_DIR}/KF6DeclarativeConfig.cmake"
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF6DeclarativeConfigVersion.cmake"
0090   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0091   COMPONENT Devel
0092 )
0093
0094 install(EXPORT
0095   KF6DeclarativeTargets
0096   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0097   FILE KF6DeclarativeTargets.cmake
0098   NAMESPACE KF6::
0099   COMPONENT Devel
0100 )
0101
0102 install(FILES
0103   "${CMAKE_CURRENT_BINARY_DIR}/kdeclarative_version.h"
0104   DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF}/KDeclarative"
0105   COMPONENT Devel
0106 )
0107
0108 include(ECMFeatureSummary)
0109 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0110
0111 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)