Warning, /frameworks/kdbusaddons/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KDBusAddons VERSION ${KF_VERSION})
0005 
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010 
0011 
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013 
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018 include(ECMQtDeclareLoggingCategory)
0019 include(ECMDeprecationSettings)
0020 
0021 set(REQUIRED_QT_VERSION 5.15.2)
0022 find_package(Qt${QT_MAJOR_VERSION}DBus ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0023 
0024 if (QT_MAJOR_VERSION STREQUAL "5")
0025     find_package(Qt5X11Extras ${REQUIRED_QT_VERSION} CONFIG)
0026 elseif (QT_MAJOR_VERSION STREQUAL "6")
0027     find_package(Qt6Gui ${REQUIRED_QT_VERSION} CONFIG) # qtx11extras_p.h
0028 endif()
0029 
0030 include(GenerateExportHeader)
0031 include(CMakePackageConfigHelpers)
0032 include(ECMSetupVersion)
0033 include(ECMGenerateHeaders)
0034 include(ECMGenerateExportHeader)
0035 include(ECMMarkNonGuiExecutable)
0036 include(ECMAddQch)
0037 
0038 include(ECMPoQmTools)
0039 
0040 ecm_setup_version(PROJECT VARIABLE_PREFIX KDBUSADDONS
0041                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdbusaddons_version.h"
0042                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5DBusAddonsConfigVersion.cmake"
0043                         SOVERSION 5)
0044 
0045 # qtx11extras_p.h is in Qt6Gui
0046 if(TARGET Qt5::X11Extras OR (TARGET Qt6::Gui AND NOT WIN32))
0047     set(HAVE_X11 TRUE)
0048 else()
0049     set(HAVE_X11 FALSE)
0050 endif()
0051 
0052 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0053 
0054 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0055 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0056 
0057 ecm_set_disabled_deprecation_versions(
0058     QT 5.15.2
0059 )
0060 
0061 ecm_install_po_files_as_qm(poqm)
0062 
0063 add_subdirectory(src)
0064 if (BUILD_TESTING)
0065     add_subdirectory(autotests)
0066     add_subdirectory(tests)
0067 endif()
0068 
0069 # create a Config.cmake and a ConfigVersion.cmake file and install them
0070 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5DBusAddons")
0071 
0072 if (BUILD_QCH)
0073     ecm_install_qch_export(
0074         TARGETS KF5DBusAddons_QCH
0075         FILE KF5DBusAddonsQchTargets.cmake
0076         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0077         COMPONENT Devel
0078     )
0079     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5DBusAddonsQchTargets.cmake\")")
0080 endif()
0081 
0082 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5DBusAddonsConfig.cmake.in"
0083                               "${CMAKE_CURRENT_BINARY_DIR}/KF5DBusAddonsConfig.cmake"
0084                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0085                               )
0086 
0087 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5DBusAddonsConfig.cmake"
0088                "${CMAKE_CURRENT_BINARY_DIR}/KF5DBusAddonsConfigVersion.cmake"
0089                "KF5DBusAddonsMacros.cmake"
0090                "KF5dbus.service.in"
0091         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092         COMPONENT Devel )
0093 
0094 install(EXPORT KF5DBusAddonsTargets  DESTINATION "${CMAKECONFIG_INSTALL_DIR}"  FILE KF5DBusAddonsTargets.cmake  NAMESPACE KF5:: )
0095 
0096 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kdbusaddons_version.h  DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons COMPONENT Devel)
0097 
0098 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0099 
0100 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)