kdav/src/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"libkdav\")
0002
0003 set(KDAV_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR_KF}/KDAV")
0004
0005 add_library(KF5DAV)
0006 add_library(KF5::DAV ALIAS KF5DAV)
0007
0008 set_target_properties(KF5DAV PROPERTIES
0009     VERSION     ${KDAV_VERSION}
0010     SOVERSION   ${KDAV_SOVERSION}
0011     EXPORT_NAME DAV
0012 )
0013
0014 target_sources(KF5DAV PRIVATE
0015     common/davcollection.cpp
0016     common/davcollectiondeletejob.cpp
0017     common/davcollectiondeletejob.h
0018     common/davcollection.h
0019     common/davcollectionmodifyjob.cpp
0020     common/davcollectionmodifyjob.h
0021     common/davcollectionsfetchjob.cpp
0022     common/davcollectionsfetchjob.h
0023     common/davcollectionsmultifetchjob.cpp
0024     common/davcollectionsmultifetchjob.h
0025     common/daverror.cpp
0026     common/daverror.h
0027     common/davitem.cpp
0028     common/davitemcreatejob.cpp
0029     common/davitemcreatejob.h
0030     common/davitemdeletejob.cpp
0031     common/davitemdeletejob.h
0032     common/davitemfetchjob.cpp
0033     common/davitemfetchjob.h
0034     common/davitem.h
0035     common/davitemmodifyjob.cpp
0036     common/davitemmodifyjob.h
0037     common/davitemsfetchjob.cpp
0038     common/davitemsfetchjob.h
0039     common/davitemslistjob.cpp
0040     common/davitemslistjob.h
0041     common/davjobbase.cpp
0042     common/davjobbase.h
0043     common/davjobbase_p.h
0044     common/davmanager.cpp
0045     common/davmanager_p.h
0046     common/davmultigetprotocol.cpp
0047     common/davmultigetprotocol_p.h
0048     common/davprincipalhomesetsfetchjob.cpp
0049     common/davprincipalhomesetsfetchjob.h
0050     common/davprincipalsearchjob.cpp
0051     common/davprincipalsearchjob.h
0052     common/davprotocolbase.cpp
0053     common/davprotocolbase_p.h
0054     common/davurl.cpp
0055     common/davurl.h
0056     common/enums.h
0057     common/etagcache.cpp
0058     common/etagcache.h
0059     common/protocolinfo.cpp
0060     common/protocolinfo.h
0061     common/utils.cpp
0062     common/utils_p.h
0063
0064     protocols/groupdavprotocol.cpp
0065     protocols/groupdavprotocol_p.h
0066
0067     #KContacts
0068     protocols/carddavprotocol.cpp
0069     protocols/carddavprotocol_p.h
0070
0071     #KCalCore
0072     protocols/caldavprotocol.cpp
0073     protocols/caldavprotocol_p.h
0074     )
0075
0076
0077 ecm_generate_headers(KDAV_Camelcase_HEADERS
0078     HEADER_NAMES
0079     DavJobBase
0080     DavCollection
0081     DavCollectionDeleteJob
0082     DavCollectionsFetchJob
0083     DavCollectionModifyJob
0084     DavCollectionsMultiFetchJob
0085     DavError
0086     DavItem
0087     DavItemCreateJob
0088     DavItemDeleteJob
0089     DavItemFetchJob
0090     DavItemModifyJob
0091     DavItemsFetchJob
0092     DavItemsListJob
0093     DavPrincipalHomesetsFetchJob
0094     DavPrincipalSearchJob
0095     DavUrl
0096     Enums
0097     EtagCache
0098     ProtocolInfo
0099     REQUIRED_HEADERS KDAV_HEADERS
0100     PREFIX KDAV
0101     RELATIVE common
0102     )
0103
0104 install(FILES
0105     ${KDAV_Camelcase_HEADERS}
0106     DESTINATION ${KDAV_INSTALL_INCLUDEDIR}/KDAV # for C++ namespace KDAV
0107     COMPONENT Devel
0108     )
0109
0110 install(FILES
0111     ${KDAV_HEADERS}
0112     ${CMAKE_CURRENT_BINARY_DIR}/kdav_export.h
0113
0114     DESTINATION ${KDAV_INSTALL_INCLUDEDIR}/kdav # for C++ namespace KDAV
0115     COMPONENT Devel
0116     )
0117
0118 ecm_qt_declare_logging_category(KF5DAV
0119     HEADER libkdav_debug.h
0120     IDENTIFIER KDAV_LOG
0121     CATEGORY_NAME kf.dav
0122     OLD_CATEGORY_NAMES org.kde.pim.kdav
0123     DESCRIPTION "KDAV"
0124     EXPORT KDAV
0125 )
0126
0127 generate_export_header(KF5DAV BASE_NAME kdav)
0128
0129 target_include_directories(KF5DAV PRIVATE
0130    common
0131    protocols
0132 )
0133
0134 target_link_libraries(KF5DAV
0135 PUBLIC
0136     KF5::CoreAddons
0137 PRIVATE
0138     Qt${QT_MAJOR_VERSION}::Xml
0139     Qt${QT_MAJOR_VERSION}::Gui
0140     KF5::KIOCore
0141     KF5::I18n
0142     )
0143
0144
0145 install(TARGETS
0146     KF5DAV
0147     EXPORT KF5DAVTargets
0148     ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0149     )
0150
0151 ecm_generate_pri_file(BASE_NAME KDAV
0152     LIB_NAME KF5DAV
0153     DEPS "KCoreAddons"
0154     FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDAV_INSTALL_INCLUDEDIR}
0155     )
0156
0157 install(FILES
0158     ${PRI_FILENAME}
0159     DESTINATION ${ECM_MKSPECS_INSTALL_DIR}
0160     )
0161
0162 target_include_directories(KF5DAV INTERFACE "$<INSTALL_INTERFACE:${KDAV_INSTALL_INCLUDEDIR}>")
0163
0164 ecm_qt_install_logging_categories(EXPORT KDAV FILE kdav.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0165
0166 if (BUILD_QCH)
0167     ecm_add_qch(
0168         KF5DAV_QCH
0169         NAME KDAV
0170         BASE_NAME KF5DAV
0171         VERSION ${KF_VERSION}
0172         ORG_DOMAIN org.kde
0173         SOURCES # using only public headers, to cover only public API
0174             ${KDAV_HEADERS}
0175         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0176         LINK_QCHS
0177             Qt5Gui_QCH
0178             KF5CoreAddons_QCH
0179         INCLUDE_DIRS
0180             ${CMAKE_CURRENT_BINARY_DIR}
0181         BLANK_MACROS
0182             KDAV_EXPORT
0183             KDAV_DEPRECATED_EXPORT
0184             KDAV_DEPRECATED
0185             "KDAV_DEPRECATED_VERSION(x, y, t)"
0186         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0187         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0188         COMPONENT Devel
0189     )
0190 endif()