frameworks/kcoreaddons/KF5CoreAddonsConfig.cmake.in

0001 @PACKAGE_INIT@
0002
0003 include(CMakeFindDependencyMacro)
0004 find_dependency(Qt@QT_MAJOR_VERSION@Core @REQUIRED_QT_VERSION@)
0005
0006 if(NOT @BUILD_SHARED_LIBS@)
0007     if(NOT WIN32)
0008         find_dependency(Threads)
0009     endif()
0010
0011     # Should be if(Inotify_FOUND) here, but for some reason this doesn't work when building statically
0012     # due to ECM's FindInotify.cmake misbehavior — see https://bugs.kde.org/show_bug.cgi?id=460656 for details.
0013     # This workaround stops CMake from failing on Linux by relying on the fact that Inotify is built into
0014     # kernel there, so no additional linking is required, resulting in an empty Inotify_LIBRARIES var.
0015     # The issue (most likely) persists on BSD, though, where Inotify is, in fact, provided by a library.
0016     if(@Inotify_LIBRARIES@)
0017         find_dependency(Inotify)
0018     endif()
0019
0020     if(@Procstat_FOUND@)
0021         find_dependency(Procstat)
0022     endif()
0023
0024     if(@HAVE_QTDBUS@)
0025         find_dependency(Qt@QT_MAJOR_VERSION@DBus @REQUIRED_QT_VERSION@)
0026     endif()
0027
0028     if (@UDev_FOUND@)
0029         find_dependency(UDev)
0030     endif()
0031 endif()
0032
0033 @PACKAGE_SETUP_AUTOMOC_VARIABLES@
0034
0035 if(CMAKE_CROSSCOMPILING AND KF5_HOST_TOOLING)
0036     find_file(KCOREADDONS_TARGETSFILE KF5CoreAddons/KF5CoreAddonsToolingTargets.cmake
0037         PATHS ${KF5_HOST_TOOLING} ${CMAKE_CURRENT_LIST_DIR}
0038         NO_DEFAULT_PATH
0039         NO_CMAKE_FIND_ROOT_PATH)
0040     include("${KCOREADDONS_TARGETSFILE}")
0041     # Check that the host tool version is the same to avoid incompatibilities.
0042     get_target_property(HOST_TOOL_VERSION KF5::desktoptojson TOOL_VERSION)
0043     if (NOT ("${HOST_TOOL_VERSION}" VERSION_EQUAL "@KF_VERSION@"))
0044         message(WARNING "Found incompatible host tool version ${HOST_TOOL_VERSION}, expected @KF_VERSION@")
0045     endif()
0046 else()
0047     include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsToolingTargets.cmake")
0048     if(CMAKE_CROSSCOMPILING AND DESKTOPTOJSON_EXECUTABLE)
0049         set_target_properties(KF5::desktoptojson PROPERTIES IMPORTED_LOCATION_NONE ${DESKTOPTOJSON_EXECUTABLE})
0050         set_target_properties(KF5::desktoptojson PROPERTIES IMPORTED_LOCATION ${DESKTOPTOJSON_EXECUTABLE})
0051     endif()
0052 endif()
0053 include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsTargets.cmake")
0054 include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsMacros.cmake")
0055 @PACKAGE_INCLUDE_QCHTARGETS@