Warning, /frameworks/kcoreaddons/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(KCoreAddons VERSION ${KF_VERSION})
0005 
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0 NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010 
0011 
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0013 
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDEGitCommitHooks)
0018 
0019 include(ECMGenerateExportHeader)
0020 include(CMakePackageConfigHelpers)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMAddQch)
0025 include(ECMSetupQtPluginMacroNames)
0026 include(ECMDeprecationSettings)
0027 include(ECMQmlModule)
0028 
0029 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0030 
0031 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0032 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0033 
0034 option(ENABLE_PCH "Enable precompile headers for faster builds" ON)
0035 option(KCOREADDONS_USE_QML "Build the QML plugin" ON)
0036 
0037 set(REQUIRED_QT_VERSION 6.5.0)
0038 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core)
0039 if (KCOREADDONS_USE_QML)
0040     find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Qml)
0041 endif()
0042 
0043 ecm_setup_qtplugin_macro_names(
0044     JSON_NONE
0045         "K_PLUGIN_FACTORY"
0046         "K_PLUGIN_CLASS"
0047     JSON_ARG2
0048         "K_PLUGIN_FACTORY_WITH_JSON"
0049         "K_PLUGIN_CLASS_WITH_JSON"
0050     CONFIG_CODE_VARIABLE
0051         PACKAGE_SETUP_AUTOMOC_VARIABLES
0052 )
0053 
0054 if(NOT WIN32)
0055     find_package(Threads REQUIRED)
0056 endif()
0057 
0058 # Configure checks for kdirwatch
0059 option(ENABLE_INOTIFY "Try to use inotify for directory monitoring" ON)
0060 if(ENABLE_INOTIFY)
0061     # Find libinotify
0062     find_package(Inotify)
0063     set_package_properties(Inotify PROPERTIES
0064         PURPOSE "Filesystem alteration notifications using inotify")
0065     set(HAVE_SYS_INOTIFY_H ${Inotify_FOUND})
0066 else()
0067     set(HAVE_SYS_INOTIFY_H FALSE)
0068 endif()
0069 
0070 set(HAVE_PROCSTAT FALSE)
0071 string(REGEX MATCH "[Bb][Ss][Dd]" BSDLIKE ${CMAKE_SYSTEM_NAME})
0072 if (BSDLIKE)
0073     option(ENABLE_PROCSTAT "Try to use libprocstat for process information (for BSD-like systems)" ON)
0074     if (ENABLE_PROCSTAT)
0075         # Find libprocstat
0076         find_package(Procstat)
0077         set_package_properties(Procstat PROPERTIES
0078             PURPOSE "Process information using libprocstat")
0079         set(HAVE_PROCSTAT ${PROCSTAT_FOUND})
0080     endif()
0081     if (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
0082         set_package_properties(Procstat PROPERTIES
0083             TYPE REQUIRED
0084         )
0085     endif()
0086 endif()
0087 
0088 if(NOT WIN32) # never relevant there
0089     find_package(Qt6DBus ${QT_MIN_VERSION} CONFIG)
0090     set(HAVE_QTDBUS ${Qt6DBus_FOUND})
0091     add_feature_info(XDGPortalDragAndDrop HAVE_QTDBUS "Drag and Drop support via xdg-desktop-portal requies QtDBus")
0092 endif()
0093 
0094 if (CMAKE_SYSTEM_NAME MATCHES "Linux")
0095     find_package(UDev) # Used by KFilesystemType
0096     set(HAVE_UDEV ${UDev_FOUND})
0097 endif()
0098 
0099 configure_file(src/lib/io/config-kdirwatch.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/lib/io/config-kdirwatch.h)
0100 
0101 configure_file(src/lib/io/config-kfilesystemtype.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/lib/io/config-kfilesystemtype.h)
0102 
0103 include(ECMPoQmTools)
0104 
0105 set(kcoreaddons_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/lib/kcoreaddons_version.h")
0106 ecm_setup_version(PROJECT VARIABLE_PREFIX KCOREADDONS
0107     VERSION_HEADER "${kcoreaddons_version_header}"
0108     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6CoreAddonsConfigVersion.cmake"
0109     SOVERSION 6
0110 )
0111 
0112 
0113 ecm_install_po_files_as_qm(poqm)
0114 
0115 kde_enable_exceptions()
0116 
0117 
0118 ecm_set_disabled_deprecation_versions(
0119     QT 6.5.0
0120 )
0121 
0122 add_subdirectory(src)
0123 if (BUILD_TESTING)
0124     add_subdirectory(autotests)
0125     add_subdirectory(tests)
0126 endif()
0127 
0128 # create a Config.cmake and a ConfigVersion.cmake file and install them
0129 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6CoreAddons")
0130 
0131 if (BUILD_QCH)
0132     ecm_install_qch_export(
0133         TARGETS KF6CoreAddons_QCH
0134         FILE KF6CoreAddonsQchTargets.cmake
0135         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0136         COMPONENT Devel
0137     )
0138     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6CoreAddonsQchTargets.cmake\")")
0139 endif()
0140 
0141 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6CoreAddonsConfig.cmake.in"
0142     "${CMAKE_CURRENT_BINARY_DIR}/KF6CoreAddonsConfig.cmake"
0143     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0144 )
0145 
0146 install(FILES
0147     "${CMAKE_CURRENT_BINARY_DIR}/KF6CoreAddonsConfig.cmake"
0148     "${CMAKE_CURRENT_BINARY_DIR}/KF6CoreAddonsConfigVersion.cmake"
0149     "${CMAKE_CURRENT_SOURCE_DIR}/KF6CoreAddonsMacros.cmake"
0150     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0151     COMPONENT Devel
0152 )
0153 
0154 install(EXPORT KF6CoreAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6CoreAddonsTargets.cmake NAMESPACE KF6::)
0155 
0156 install(FILES ${kcoreaddons_version_header} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCoreAddons COMPONENT Devel)
0157 
0158 include(ECMFeatureSummary)
0159 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0160 
0161 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)