kcontacts/src/CMakeLists.txt

0001 add_library(KF5Contacts)
0002 add_library(KF5::Contacts ALIAS KF5Contacts)
0003
0004 target_sources(KF5Contacts PRIVATE
0005     address.cpp
0006     addressee.cpp
0007     addressee.h
0008     addresseehelper.cpp
0009     addresseehelper.h
0010     addresseelist.h
0011     addressformat.cpp
0012     addressformatparser.cpp
0013     addressformatscript.cpp
0014     addressformatter.cpp
0015     address.h
0016     calendarurl.cpp
0017     calendarurl.h
0018     clientpidmap.cpp
0019     clientpidmap.h
0020     contactgroup.cpp
0021     contactgroup.h
0022     contactgrouptool.cpp
0023     contactgrouptool.h
0024     converter/ldifconverter.cpp
0025     converter/ldifconverter.h
0026     converter/vcardconverter.cpp
0027     converter/vcardconverter.h
0028     email.cpp
0029     email.h
0030     field.cpp
0031     fieldgroup.cpp
0032     fieldgroup.h
0033     field.h
0034     gender.cpp
0035     gender.h
0036     geo.cpp
0037     geo.h
0038     impp.cpp
0039     impp.h
0040     key.cpp
0041     key.h
0042     lang.cpp
0043     lang.h
0044     ldif.cpp
0045     ldif_p.h
0046     namespace.cpp
0047     nickname.cpp
0048     nickname.h
0049     note.cpp
0050     note.h
0051     org.cpp
0052     org.h
0053     parametermap_p.h
0054     phonenumber.cpp
0055     phonenumber.h
0056     picture.cpp
0057     picture.h
0058     related.cpp
0059     related.h
0060     resourcelocatorurl.cpp
0061     resourcelocatorurl.h
0062     role.cpp
0063     role.h
0064     secrecy.cpp
0065     secrecy.h
0066     sound.cpp
0067     sound.h
0068     timezone.cpp
0069     timezone.h
0070     title.cpp
0071     title.h
0072     vcarddrag.cpp
0073     vcarddrag.h
0074     vcardparser/vcard.cpp
0075     vcardparser/vcardline.cpp
0076     vcardparser/vcardline_p.h
0077     vcardparser/vcardparser.cpp
0078     vcardparser/vcardparser_p.h
0079     vcardparser/vcard_p.h
0080     vcardtool.cpp
0081     vcardtool_p.h
0082
0083
0084   kcontacts.qrc
0085   improtocols/improtocols.qrc
0086 )
0087
0088 ecm_qt_declare_logging_category(KF5Contacts
0089     HEADER kcontacts_debug.h
0090     IDENTIFIER KCONTACTS_LOG
0091     CATEGORY_NAME kf.contacts
0092     OLD_CATEGORY_NAMES log_kcontacts org.kde.pim.kcontacts
0093     DESCRIPTION "KContacts"
0094     EXPORT KCONTACTS
0095 )
0096
0097 ecm_generate_export_header(KF5Contacts
0098     EXPORT_FILE_NAME kcontacts_export.h
0099     BASE_NAME kcontacts
0100     GROUP_BASE_NAME KF
0101     VERSION ${KF_VERSION}
0102     DEPRECATED_BASE_VERSION 0
0103     DEPRECATION_VERSIONS 5.88 5.89 5.92
0104     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0105 )
0106
0107 target_include_directories(KF5Contacts INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KContacts>")
0108 set(KContacts_BUILD_INCLUDE_DIRS
0109     ${KContacts_SOURCE_DIR}/src
0110     ${KContacts_BINARY_DIR}/src
0111     ${KContacts_SOURCE_DIR}/src/vcardparser
0112 )
0113 target_include_directories(KF5Contacts PUBLIC "$<BUILD_INTERFACE:${KContacts_BUILD_INCLUDE_DIRS}>")
0114
0115 target_link_libraries(KF5Contacts
0116 PUBLIC
0117     Qt${QT_MAJOR_VERSION}::Core
0118     Qt${QT_MAJOR_VERSION}::Gui
0119 PRIVATE
0120     KF5::CoreAddons
0121     KF5::ConfigCore
0122     KF5::I18n
0123     KF5::I18nLocaleData
0124     KF5::Codecs # for the vcard parser
0125 )
0126
0127 if (TARGET Qt6::Core5Compat)
0128     target_link_libraries(KF5Contacts PRIVATE Qt6::Core5Compat) # QTextCodec
0129 endif()
0130
0131 set_target_properties(KF5Contacts PROPERTIES
0132     VERSION ${KContacts_VERSION}
0133     SOVERSION ${KContacts_SOVERSION}
0134     EXPORT_NAME Contacts
0135 )
0136
0137 install(TARGETS KF5Contacts EXPORT KF5ContactsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0138
0139 ecm_generate_headers(KContacts_CamelCase_HEADERS
0140   HEADER_NAMES
0141   Address
0142   AddressFormat
0143   Addressee
0144   AddresseeList
0145   CalendarUrl
0146   ContactGroup
0147   ContactGroupTool
0148   Email
0149   Field
0150   Geo
0151   Gender
0152   Key
0153   Lang
0154   Namespace
0155   Impp
0156   PhoneNumber
0157   Picture
0158   Related
0159   ResourceLocatorUrl
0160   Secrecy
0161   Sound
0162   TimeZone
0163   Title
0164   Role
0165   Note
0166   Org
0167   NickName
0168   VCardDrag
0169   FieldGroup
0170   ClientPidMap
0171   PREFIX KContacts
0172   REQUIRED_HEADERS KContacts_HEADERS
0173 )
0174
0175 add_subdirectory(converter)
0176
0177 install(FILES
0178     ${CMAKE_CURRENT_BINARY_DIR}/kcontacts_export.h
0179     ${KContacts_HEADERS}
0180     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KContacts/kcontacts
0181     COMPONENT Devel
0182 )
0183
0184 install(FILES
0185     ${KContacts_CamelCase_HEADERS}
0186     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KContacts/KContacts
0187     COMPONENT Devel
0188 )
0189
0190 ecm_qt_install_logging_categories(
0191     EXPORT KCONTACTS
0192     FILE kcontacts.categories
0193     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0194 )
0195
0196 ecm_generate_pri_file(BASE_NAME KContacts LIB_NAME KF5Contacts DEPS "KCoreAddons" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KContacts)
0197 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0198
0199 if(BUILD_QCH)
0200     ecm_add_qch(
0201         KF5Contacts_QCH
0202         NAME KContacts
0203         BASE_NAME KF5Contacts
0204         VERSION ${KContacts_VERSION}
0205         ORG_DOMAIN org.kde
0206         SOURCES # using only public headers, to cover only public API
0207             ${KContacts_HEADERS}
0208             "${CMAKE_SOURCE_DIR}/docs/AddressFormat.md"
0209         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0210         LINK_QCHS
0211             Qt5Core_QCH
0212         INCLUDE_DIRS
0213             ${KContacts_BUILD_INCLUDE_DIRS}
0214         BLANK_MACROS
0215             KCONTACTS_EXPORT
0216             "KCONTACTS_DEPRECATED_VERSION(x, y, t)"
0217             "KCONTACTS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0218             "KCONTACTS_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0219             "KCONTACTS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0220         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0221         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0222         COMPONENT Devel
0223     )
0224 endif()