frameworks/kcontacts/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0005
0006 project(KContacts VERSION ${KF_VERSION})
0007
0008 # ECM setup
0009 include(FeatureSummary)
0010 find_package(ECM 5.106.0 NO_MODULE)
0011 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0012 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0013
0014 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0015 set(CMAKE_AUTORCC ON)
0016
0017 set(REQUIRED_QT_VERSION 5.15.2)
0018
0019 include(KDEInstallDirs)
0020 include(KDECMakeSettings)
0021 include(KDEGitCommitHooks)
0022 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0023
0024 include(ECMGenerateExportHeader)
0025 include(ECMGenerateHeaders)
0026 include(ECMGeneratePriFile)
0027 include(ECMGenerateExportHeader)
0028 include(ECMDeprecationSettings)
0029
0030 include(ECMSetupVersion)
0031 include(ECMQtDeclareLoggingCategory)
0032 include(ECMAddQch)
0033
0034 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0035
0036 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0037 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0038
0039 set(KCONTACTS_LIB_VERSION ${KF_VERSION})
0040
0041 ecm_setup_version(PROJECT VARIABLE_PREFIX KContacts
0042                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kcontacts_version.h"
0043                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ContactsConfigVersion.cmake"
0044                         SOVERSION 5
0045 )
0046
0047 ########### Find packages ###########
0048 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} NO_MODULE COMPONENTS Gui Quick)
0049 set_package_properties(Qt${QT_MAJOR_VERSION}Gui PROPERTIES
0050     TYPE REQUIRED
0051     PURPOSE "Basic library component"
0052 )
0053 set_package_properties(Qt${QT_MAJOR_VERSION}Quick PROPERTIES
0054     TYPE OPTIONAL
0055     PURPOSE "QtQuick plugin"
0056 )
0057 find_package(KF5 ${KF_DEP_VERSION} REQUIRED COMPONENTS CoreAddons I18n Config Codecs)
0058 if (QT_MAJOR_VERSION STREQUAL "6")
0059     find_package(Qt6Core5Compat)
0060 endif()
0061
0062 ########### Targets ###########
0063
0064 add_definitions(-DTRANSLATION_DOMAIN=\"kcontacts5\")
0065 ki18n_install(po)
0066
0067 ecm_set_disabled_deprecation_versions(
0068     QT 5.15.2
0069     KF 5.95.0
0070 )
0071
0072 add_subdirectory(src)
0073
0074 if(BUILD_TESTING)
0075     add_subdirectory(autotests)
0076     add_subdirectory(tests)
0077 endif()
0078
0079 ########### CMake Config Files ###########
0080 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Contacts")
0081
0082 if (BUILD_QCH)
0083     ecm_install_qch_export(
0084         TARGETS KF5Contacts_QCH
0085         FILE KF5ContactsQchTargets.cmake
0086         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087         COMPONENT Devel
0088     )
0089     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ContactsQchTargets.cmake\")")
0090 endif()
0091
0092 configure_package_config_file(
0093   "${CMAKE_CURRENT_SOURCE_DIR}/KF5ContactsConfig.cmake.in"
0094   "${CMAKE_CURRENT_BINARY_DIR}/KF5ContactsConfig.cmake"
0095   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0096 )
0097
0098 install(FILES
0099   "${CMAKE_CURRENT_BINARY_DIR}/KF5ContactsConfig.cmake"
0100   "${CMAKE_CURRENT_BINARY_DIR}/KF5ContactsConfigVersion.cmake"
0101   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102   COMPONENT Devel
0103 )
0104
0105 install(EXPORT KF5ContactsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5ContactsTargets.cmake NAMESPACE KF5::)
0106
0107 install(FILES
0108    ${CMAKE_CURRENT_BINARY_DIR}/kcontacts_version.h
0109   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KContacts COMPONENT Devel
0110 )
0111
0112 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0113
0114 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)