kconfigwidgets/src/CMakeLists.txt

0001 add_library(KF6ConfigWidgets)
0002 add_library(KF6::ConfigWidgets ALIAS KF6ConfigWidgets)
0003
0004 set_target_properties(KF6ConfigWidgets PROPERTIES
0005     VERSION     ${KCONFIGWIDGETS_VERSION}
0006     SOVERSION   ${KCONFIGWIDGETS_SOVERSION}
0007     EXPORT_NAME ConfigWidgets
0008 )
0009
0010 target_sources(KF6ConfigWidgets PRIVATE
0011   kcodecaction.cpp
0012   kcolorschememenu.cpp
0013   kcommandbar.cpp
0014   kcommandbarmodel_p.cpp
0015   kconfigdialog.cpp
0016   kconfigviewstatesaver.cpp
0017   kconfigdialogmanager.cpp
0018   khelpclient.cpp
0019   khamburgermenu.cpp
0020   khamburgermenuhelpers.cpp
0021   klanguagebutton.cpp
0022   klanguagename.cpp
0023   kopenaction.cpp
0024   krecentfilesaction.cpp
0025   kstandardaction.cpp
0026
0027   kcodecaction.h
0028   kcommandbar.h
0029   kcommandbarmodel_p.h
0030   kconfigdialog.h
0031   kconfigviewstatesaver.h
0032   kconfigdialogmanager.h
0033   khelpclient.h
0034   khamburgermenu.h
0035   khamburgermenuhelpers_p.h
0036   klanguagebutton.h
0037   klanguagename.h
0038   kopenaction_p.h
0039   krecentfilesaction.h
0040   kstandardaction.h
0041 )
0042
0043 ecm_qt_declare_logging_category(KF6ConfigWidgets
0044     HEADER kconfigwidgets_debug.h
0045     IDENTIFIER KCONFIG_WIDGETS_LOG
0046     CATEGORY_NAME kf.configwidgets
0047     OLD_CATEGORY_NAMES kf5.kconfigwidgets
0048     DESCRIPTION "KConfigWidgets"
0049     EXPORT KCONFIGWIDGETS
0050 )
0051
0052 ecm_generate_export_header(KF6ConfigWidgets
0053     BASE_NAME KConfigWidgets
0054     GROUP_BASE_NAME KF
0055     VERSION ${KF_VERSION}
0056     USE_VERSION_HEADER
0057     DEPRECATED_BASE_VERSION 0
0058     DEPRECATION_VERSIONS
0059     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0060 )
0061
0062 target_include_directories(KF6ConfigWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets>")
0063
0064 target_link_libraries(KF6ConfigWidgets
0065   PUBLIC
0066     KF6::WidgetsAddons # For K*Action, KPage*, KViewStateSerializer, KAcceleratorManager, K*GuiItem
0067     KF6::ConfigGui # KStandardAction uses KStandardShortcut
0068     KF6::ColorScheme
0069   PRIVATE
0070     KF6::CoreAddons # KAboutData, KFuzzymatcher
0071     KF6::GuiAddons # KColorScheme uses KColorUtils
0072     KF6::I18n # For action and widget texts
0073 )
0074
0075 target_link_libraries(KF6ConfigWidgets
0076   PRIVATE
0077   KF6::Codecs # KCodecActions uses KCharsets, KEncodingProber
0078 )
0079
0080 ecm_generate_headers(KConfigWidgets_HEADERS
0081   HEADER_NAMES
0082   KCodecAction
0083   KColorSchemeMenu
0084   KCommandBar
0085   KConfigDialog
0086   KConfigViewStateSaver
0087   KConfigDialogManager
0088   KHamburgerMenu
0089   KHelpClient
0090   KLanguageButton
0091   KLanguageName
0092   KRecentFilesAction
0093   KViewStateMaintainer
0094   KStandardAction
0095
0096   REQUIRED_HEADERS KConfigWidgets_HEADERS
0097 )
0098
0099 install(TARGETS KF6ConfigWidgets EXPORT KF6ConfigWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0100
0101 install(FILES
0102   ${CMAKE_CURRENT_BINARY_DIR}/kconfigwidgets_export.h
0103   ${KConfigWidgets_HEADERS}
0104   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets COMPONENT Devel
0105 )
0106
0107 install( FILES entry.desktop  DESTINATION  ${KDE_INSTALL_LOCALEDIR}/en_US RENAME kf6_entry.desktop )
0108
0109 ecm_qt_install_logging_categories(
0110     EXPORT KCONFIGWIDGETS
0111     FILE kconfigwidgets.categories
0112     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0113 )
0114
0115 if(BUILD_DESIGNERPLUGIN)
0116     add_subdirectory(designer)
0117 endif()
0118
0119 if(BUILD_QCH)
0120     ecm_add_qch(
0121         KF6ConfigWidgets_QCH
0122         NAME KConfigWidgets
0123         BASE_NAME KF6ConfigWidgets
0124         VERSION ${KF_VERSION}
0125         ORG_DOMAIN org.kde
0126         SOURCES # using only public headers, to cover only public API
0127             ${KConfigWidgets_HEADERS}
0128         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0129         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0130         LINK_QCHS
0131             KF6Codecs_QCH
0132             KF6WidgetsAddons_QCH
0133             KF6Config_QCH
0134             KF6Auth_QCH
0135         INCLUDE_DIRS
0136             ${CMAKE_CURRENT_BINARY_DIR}
0137         BLANK_MACROS
0138             KCONFIGWIDGETS_EXPORT
0139             KCONFIGWIDGETS_DEPRECATED
0140             KCONFIGWIDGETS_DEPRECATED_EXPORT
0141             "KCONFIGWIDGETS_DEPRECATED_VERSION(x, y, t)"
0142             "KCONFIGWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0143             "KCONFIGWIDGETS_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0144             "KCONFIGWIDGETS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0145         PREDEFINED_MACROS
0146             "KCONFIGWIDGETS_ENABLE_DEPRECATED_SINCE(x, y)=1"
0147             "KCONFIGWIDGETS_BUILD_DEPRECATED_SINCE(x, y)=1"
0148         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0149         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0150         COMPONENT Devel
0151     )
0152 endif()