kconfigwidgets/src/CMakeLists.txt

0001 add_library(KF6ConfigWidgets)
0002 add_library(KF6::ConfigWidgets ALIAS KF6ConfigWidgets)
0003
0004 set_target_properties(KF6ConfigWidgets PROPERTIES
0005     VERSION     ${KCONFIGWIDGETS_VERSION}
0006     SOVERSION   ${KCONFIGWIDGETS_SOVERSION}
0007     EXPORT_NAME ConfigWidgets
0008 )
0009
0010 target_sources(KF6ConfigWidgets PRIVATE
0011   kcodecaction.cpp
0012   kcolorschememenu.cpp
0013   kcommandbar.cpp
0014   kcommandbarmodel_p.cpp
0015   kconfigdialog.cpp
0016   kconfigviewstatesaver.cpp
0017   kconfigdialogmanager.cpp
0018   khelpclient.cpp
0019   khamburgermenu.cpp
0020   khamburgermenuhelpers.cpp
0021   klanguagebutton.cpp
0022   klanguagename.cpp
0023   kopenaction.cpp
0024   krecentfilesaction.cpp
0025   kstandardaction.cpp
0026
0027   kcodecaction.h
0028   kcommandbar.h
0029   kcommandbarmodel_p.h
0030   kconfigdialog.h
0031   kconfigviewstatesaver.h
0032   kconfigdialogmanager.h
0033   khelpclient.h
0034   khamburgermenu.h
0035   khamburgermenuhelpers_p.h
0036   klanguagebutton.h
0037   klanguagename.h
0038   kopenaction_p.h
0039   krecentfilesaction.h
0040   kstandardaction.h
0041 )
0042
0043 ecm_qt_declare_logging_category(KF6ConfigWidgets
0044     HEADER kconfigwidgets_debug.h
0045     IDENTIFIER KCONFIG_WIDGETS_LOG
0046     CATEGORY_NAME kf.configwidgets
0047     OLD_CATEGORY_NAMES kf5.kconfigwidgets
0048     DESCRIPTION "KConfigWidgets"
0049     EXPORT KCONFIGWIDGETS
0050 )
0051
0052 ecm_generate_export_header(KF6ConfigWidgets
0053     BASE_NAME KConfigWidgets
0054     GROUP_BASE_NAME KF
0055     VERSION ${KF_VERSION}
0056     USE_VERSION_HEADER
0057     DEPRECATED_BASE_VERSION 0
0058     DEPRECATION_VERSIONS
0059     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0060 )
0061
0062 target_include_directories(KF6ConfigWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets>")
0063
0064 target_link_libraries(KF6ConfigWidgets
0065   PUBLIC
0066     KF6::WidgetsAddons # For K*Action, KPage*, KViewStateSerializer, KAcceleratorManager, K*GuiItem
0067     KF6::ConfigGui # KStandardAction uses KStandardShortcut
0068     KF6::ColorScheme
0069   PRIVATE
0070     KF6::CoreAddons # KAboutData, KFuzzymatcher
0071     KF6::GuiAddons # KColorScheme uses KColorUtils
0072     KF6::I18n # For action and widget texts
0073     KF6::Codecs # KCodecActions uses KCharsets, KEncodingProber
0074 )
0075 if (HAVE_DBUS)
0076     target_link_libraries(KF6ConfigWidgets
0077         PRIVATE
0078         Qt::DBus # KRecentFilesAction to send call to ActivityManager
0079     )
0080 endif()
0081
0082 ecm_generate_headers(KConfigWidgets_HEADERS
0083   HEADER_NAMES
0084   KCodecAction
0085   KColorSchemeMenu
0086   KCommandBar
0087   KConfigDialog
0088   KConfigViewStateSaver
0089   KConfigDialogManager
0090   KHamburgerMenu
0091   KHelpClient
0092   KLanguageButton
0093   KLanguageName
0094   KRecentFilesAction
0095   KViewStateMaintainer
0096   KStandardAction
0097
0098   REQUIRED_HEADERS KConfigWidgets_HEADERS
0099 )
0100
0101 install(TARGETS KF6ConfigWidgets EXPORT KF6ConfigWidgetsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0102
0103 install(FILES
0104   ${CMAKE_CURRENT_BINARY_DIR}/kconfigwidgets_export.h
0105   ${KConfigWidgets_HEADERS}
0106   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets COMPONENT Devel
0107 )
0108
0109 install( FILES entry.desktop  DESTINATION  ${KDE_INSTALL_LOCALEDIR}/en_US RENAME kf6_entry.desktop )
0110
0111 ecm_qt_install_logging_categories(
0112     EXPORT KCONFIGWIDGETS
0113     FILE kconfigwidgets.categories
0114     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0115 )
0116
0117 if(BUILD_DESIGNERPLUGIN)
0118     add_subdirectory(designer)
0119 endif()
0120
0121 if(BUILD_QCH)
0122     ecm_add_qch(
0123         KF6ConfigWidgets_QCH
0124         NAME KConfigWidgets
0125         BASE_NAME KF6ConfigWidgets
0126         VERSION ${KF_VERSION}
0127         ORG_DOMAIN org.kde
0128         SOURCES # using only public headers, to cover only public API
0129             ${KConfigWidgets_HEADERS}
0130         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0131         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0132         LINK_QCHS
0133             KF6Codecs_QCH
0134             KF6WidgetsAddons_QCH
0135             KF6Config_QCH
0136             KF6Auth_QCH
0137         INCLUDE_DIRS
0138             ${CMAKE_CURRENT_BINARY_DIR}
0139         BLANK_MACROS
0140             KCONFIGWIDGETS_EXPORT
0141             KCONFIGWIDGETS_DEPRECATED
0142             KCONFIGWIDGETS_DEPRECATED_EXPORT
0143             "KCONFIGWIDGETS_DEPRECATED_VERSION(x, y, t)"
0144             "KCONFIGWIDGETS_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0145             "KCONFIGWIDGETS_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0146             "KCONFIGWIDGETS_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0147         PREDEFINED_MACROS
0148             "KCONFIGWIDGETS_ENABLE_DEPRECATED_SINCE(x, y)=1"
0149             "KCONFIGWIDGETS_BUILD_DEPRECATED_SINCE(x, y)=1"
0150         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0151         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0152         COMPONENT Devel
0153     )
0154 endif()