src/qml/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2023 Alexander Lohnau <alexander.lohnau@gmx.de>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 add_library(KF6ConfigQml)
0005 add_library(KF6::ConfigQml ALIAS KF6ConfigQml)
0006
0007 set_target_properties(KF6ConfigQml PROPERTIES
0008     VERSION     ${KCONFIG_VERSION}
0009     SOVERSION   ${KCONFIG_SOVERSION}
0010     EXPORT_NAME ConfigQml
0011 )
0012
0013 target_sources(KF6ConfigQml PRIVATE
0014     kconfigpropertymap.cpp
0015 )
0016
0017 ecm_generate_export_header(KF6ConfigQml
0018     BASE_NAME KConfigQml
0019     GROUP_BASE_NAME KF
0020     VERSION ${KF_VERSION}
0021     USE_VERSION_HEADER
0022     VERSION_BASE_NAME KConfig
0023     DEPRECATED_BASE_VERSION 0
0024     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0025 )
0026
0027 target_link_libraries(KF6ConfigQml
0028   PUBLIC
0029     KF6::ConfigCore # KCoreConfigSkeleton, in ConfigPropertyMap
0030     Qt6::Qml
0031 )
0032
0033 ecm_generate_headers(KConfigQml_HEADERS
0034     HEADER_NAMES
0035     KConfigPropertyMap
0036
0037     REQUIRED_HEADERS KConfigQml_HEADERS
0038 )
0039 target_include_directories(KF6ConfigQml
0040     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfig;${KDE_INSTALL_INCLUDEDIR_KF}/KConfigQml>")
0041
0042 install(TARGETS KF6ConfigQml EXPORT KF6ConfigTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0043 install(FILES
0044   ${CMAKE_CURRENT_BINARY_DIR}/kconfigqml_export.h
0045   ${KConfigQml_HEADERS}
0046   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigQml COMPONENT Devel
0047 )
0048
0049
0050 # The QML plugin
0051 ecm_add_qml_module(kconfigqmlplugin URI org.kde.config GENERATE_PLUGIN_SOURCE)
0052 target_sources(kconfigqmlplugin PRIVATE types.cpp)
0053 target_link_libraries(kconfigqmlplugin PRIVATE
0054     Qt6::Core
0055     Qt6::Qml
0056     KF6::ConfigCore
0057 )
0058
0059 ecm_finalize_qml_module(kconfigqmlplugin DESTINATION ${KDE_INSTALL_QMLDIR})
0060