src/core/CMakeLists.txt

0001 add_library(KF5ConfigCore)
0002 add_library(KF5::ConfigCore ALIAS KF5ConfigCore)
0003
0004 target_sources(KF5ConfigCore PRIVATE
0005    kconfig.cpp
0006    kconfigbase.cpp
0007    kconfigdata.cpp
0008    kconfiggroup.cpp
0009    kconfigbackend.cpp
0010    kconfigini.cpp
0011    kdesktopfile.cpp
0012    ksharedconfig.cpp
0013    kcoreconfigskeleton.cpp
0014    kauthorized.cpp
0015    kemailsettings.cpp
0016    kconfigwatcher.cpp
0017 )
0018
0019 ecm_qt_declare_logging_category(KF5ConfigCore
0020     HEADER kconfig_core_log_settings.h
0021     IDENTIFIER KCONFIG_CORE_LOG
0022     CATEGORY_NAME kf.config.core
0023     OLD_CATEGORY_NAMES kf5.kconfig.core
0024     DESCRIPTION "KConfig Core"
0025     EXPORT KCONFIG
0026 )
0027
0028 configure_file(config-kconfig.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kconfig.h )
0029
0030 ecm_generate_export_header(KF5ConfigCore
0031     BASE_NAME KConfigCore
0032     GROUP_BASE_NAME KF
0033     VERSION ${KF_VERSION}
0034     DEPRECATED_BASE_VERSION 0
0035     DEPRECATION_VERSIONS 4.0 5.0 5.24 5.42 5.82 5.89 5.103
0036     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0037 )
0038
0039 target_compile_definitions(KF5ConfigCore
0040     PRIVATE
0041         KCONF_UPDATE_INSTALL_LOCATION="${KDE_INSTALL_FULL_LIBEXECDIR_KF}/$<TARGET_FILE_NAME:KF5::kconf_update>"
0042 )
0043
0044 target_include_directories(KF5ConfigCore
0045     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfig;${KDE_INSTALL_INCLUDEDIR_KF}/KConfigCore>"
0046 )
0047
0048 target_link_libraries(KF5ConfigCore PUBLIC Qt${QT_MAJOR_VERSION}::Core)
0049
0050 if(KCONFIG_USE_DBUS)
0051     target_link_libraries(KF5ConfigCore PRIVATE Qt${QT_MAJOR_VERSION}::DBus)
0052 endif()
0053
0054 set_target_properties(KF5ConfigCore PROPERTIES VERSION   ${KCONFIG_VERSION}
0055                                                SOVERSION ${KCONFIG_SOVERSION}
0056                                                EXPORT_NAME ConfigCore
0057 )
0058
0059 ecm_generate_headers(KConfigCore_HEADERS
0060   HEADER_NAMES
0061   KAuthorized
0062   KConfig
0063   KConfigBase
0064   KConfigGroup
0065   KDesktopFile
0066   KSharedConfig
0067   KCoreConfigSkeleton
0068   KEMailSettings
0069   ConversionCheck
0070   KConfigWatcher
0071
0072   REQUIRED_HEADERS KConfigCore_HEADERS
0073 )
0074
0075 install(TARGETS KF5ConfigCore EXPORT KF5ConfigTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0076
0077 install(FILES
0078   ${CMAKE_CURRENT_BINARY_DIR}/kconfigcore_export.h
0079   ${KConfigCore_HEADERS}
0080   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigCore COMPONENT Devel
0081 )
0082
0083 # make available to ecm_add_qch in parent folder
0084 set(KConfigCore_APIDOX_SRCS ${KConfigCore_HEADERS} PARENT_SCOPE)
0085 set(KConfigCore_APIDOX_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR} PARENT_SCOPE)
0086
0087 include(ECMGeneratePriFile)
0088 ecm_generate_pri_file(
0089   BASE_NAME KConfigCore
0090   LIB_NAME KF5ConfigCore
0091   DEPS "core"
0092   FILENAME_VAR PRI_FILENAME
0093   INCLUDE_INSTALL_DIRS
0094     ${KDE_INSTALL_INCLUDEDIR_KF}/KConfig
0095     ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigCore
0096 )
0097 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})