frameworks/kconfig/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KConfig VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0015 include(KDECMakeSettings)
0016 include(KDEGitCommitHooks)
0017
0018 include(ECMGenerateExportHeader)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMMarkNonGuiExecutable)
0022 include(ECMPoQmTools)
0023 include(ECMAddQch)
0024 include(ECMQtDeclareLoggingCategory)
0025 include(ECMDeprecationSettings)
0026
0027 set(REQUIRED_QT_VERSION 5.15.2)
0028
0029 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Xml)
0030 option(KCONFIG_USE_GUI "Build components using Qt${QT_MAJOR_VERSION}Gui" ON)
0031 if(KCONFIG_USE_GUI)
0032     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Gui)
0033 endif()
0034
0035 option(KCONFIG_USE_QML "Build components using Qt${QT_MAJOR_VERSION}Qml" ON)
0036
0037 if(KCONFIG_USE_QML)
0038     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED COMPONENTS Qml)
0039 endif()
0040
0041 if (NOT ANDROID)
0042     set(default_kconfig_use_dbus ON)
0043     if(WIN32)
0044         set(default_kconfig_use_dbus OFF)
0045     endif()
0046     option(KCONFIG_USE_DBUS "Build components using Qt${QT_MAJOR_VERSION}DBus" ${default_kconfig_use_dbus})
0047     if(KCONFIG_USE_DBUS)
0048         find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0049     endif()
0050 else()
0051     set(KCONFIG_USE_DBUS Off)
0052 endif()
0053
0054 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0055
0056 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0057 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0058
0059 ecm_setup_version(PROJECT VARIABLE_PREFIX KCONFIG
0060                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kconfig_version.h"
0061                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigConfigVersion.cmake"
0062                         SOVERSION 5)
0063
0064 ecm_set_disabled_deprecation_versions(
0065     QT 5.15.2
0066 )
0067
0068 add_subdirectory(src)
0069 if (BUILD_TESTING)
0070     add_subdirectory(autotests)
0071 endif()
0072
0073 include (ECMPoQmTools)
0074 ecm_install_po_files_as_qm(poqm)
0075
0076
0077 # create a Config.cmake and a ConfigVersion.cmake file and install them
0078 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Config")
0079
0080 if (BUILD_QCH)
0081     ecm_install_qch_export(
0082         TARGETS KF5Config_QCH
0083         FILE KF5ConfigQchTargets.cmake
0084         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0085         COMPONENT Devel
0086     )
0087     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ConfigQchTargets.cmake\")")
0088 endif()
0089
0090 include(CMakePackageConfigHelpers)
0091
0092 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5ConfigConfig.cmake.in"
0093                               "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigConfig.cmake"
0094                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0095                               )
0096
0097 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigConfig.cmake"
0098                "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigConfigVersion.cmake"
0099                "${CMAKE_CURRENT_SOURCE_DIR}/KF5ConfigMacros.cmake"
0100         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101         COMPONENT Devel )
0102
0103
0104 install(EXPORT KF5ConfigTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0105         FILE KF5ConfigTargets.cmake NAMESPACE KF5:: COMPONENT Devel)
0106
0107
0108 install(EXPORT KF5ConfigCompilerTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0109         FILE KF5ConfigCompilerTargets.cmake NAMESPACE KF5:: COMPONENT Devel)
0110
0111 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kconfig_version.h
0112         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfig COMPONENT Devel)
0113
0114
0115 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0116
0117 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)