frameworks/kcompletion/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KCompletion VERSION ${KF_VERSION})
0006
0007 # ECM setup
0008 include(FeatureSummary)
0009 find_package(ECM 5.249.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019
0020 include(ECMGenerateExportHeader)
0021 include(ECMSetupVersion)
0022 include(ECMGenerateHeaders)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMDeprecationSettings)
0025 include(CMakePackageConfigHelpers)
0026 include(CMakeDependentOption)
0027
0028 include(ECMAddQch)
0029 include(ECMPoQmTools)
0030
0031 set(kcompletion_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kcompletion_version.h")
0032 ecm_setup_version(PROJECT VARIABLE_PREFIX KCOMPLETION
0033   VERSION_HEADER "${kcompletion_version_header}"
0034   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6CompletionConfigVersion.cmake"
0035   SOVERSION 6)
0036
0037 # Dependencies
0038 set(REQUIRED_QT_VERSION 6.5.0)
0039
0040 find_package(Qt6 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Widgets)
0041
0042 find_package(KF6Codecs ${KF_DEP_VERSION} REQUIRED)
0043 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0044 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0045
0046 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0047
0048 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0049 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0050
0051 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0052 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0053
0054 ecm_set_disabled_deprecation_versions(
0055     QT 6.5
0056     KF 5.240
0057 )
0058
0059 ecm_install_po_files_as_qm(poqm)
0060
0061 add_subdirectory(src)
0062 if (BUILD_TESTING)
0063     add_subdirectory(tests)
0064     add_subdirectory(autotests)
0065 endif()
0066
0067 # create a Config.cmake and a ConfigVersion.cmake file and install them
0068 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Completion")
0069
0070 if (BUILD_QCH)
0071     ecm_install_qch_export(
0072         TARGETS KF6Completion_QCH
0073         FILE KF6CompletionQchTargets.cmake
0074         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0075         COMPONENT Devel
0076     )
0077     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6CompletionQchTargets.cmake\")")
0078 endif()
0079
0080 include(CMakePackageConfigHelpers)
0081
0082 configure_package_config_file(
0083   "${CMAKE_CURRENT_SOURCE_DIR}/KF6CompletionConfig.cmake.in"
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF6CompletionConfig.cmake"
0085   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0086 )
0087
0088 install(FILES
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF6CompletionConfig.cmake"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF6CompletionConfigVersion.cmake"
0091   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092   COMPONENT Devel
0093 )
0094
0095 install(EXPORT KF6CompletionTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6CompletionTargets.cmake NAMESPACE KF6:: )
0096
0097 install(FILES
0098    ${kcompletion_version_header}
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion COMPONENT Devel
0100 )
0101
0102 include(ECMFeatureSummary)
0103 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0104
0105 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)