kcolorscheme/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2023 David Redondo <kde@david-redondo.de>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 add_library(KF6ColorScheme)
0005 add_library(KF6::ColorScheme ALIAS KF6ColorScheme)
0006
0007 set_target_properties(KF6ColorScheme PROPERTIES
0008     VERSION     ${KCOLORSCHEME_VERSION}
0009     SOVERSION   ${KCOLORSCHEME_SOVERSION}
0010     EXPORT_NAME ColorScheme
0011 )
0012
0013 target_sources(KF6ColorScheme PRIVATE
0014   kcolorscheme.cpp
0015   kcolorschememanager.cpp
0016   kcolorschememodel.cpp
0017   kstatefulbrush.cpp
0018 )
0019
0020 ecm_qt_declare_logging_category(KF6ColorScheme
0021     HEADER kcolorscheme_debug.h
0022     IDENTIFIER KCOLORSCHEME
0023     CATEGORY_NAME kf.colorscheme
0024     DESCRIPTION "KColorScheme"
0025     EXPORT KCOLORSCHEME
0026 )
0027
0028 ecm_generate_export_header(KF6ColorScheme
0029     BASE_NAME KColorScheme
0030     GROUP_BASE_NAME KF
0031     VERSION ${KF_VERSION}
0032     USE_VERSION_HEADER
0033     DEPRECATED_BASE_VERSION 0
0034     DEPRECATION_VERSIONS
0035     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0036 )
0037
0038 target_include_directories(KF6ColorScheme INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KColorScheme>")
0039
0040 target_link_libraries(KF6ColorScheme
0041   PUBLIC
0042     KF6::ConfigCore
0043     Qt6::Gui
0044   PRIVATE
0045     KF6::ConfigGui # ### this one is not directly used but has to be loaded in order for QColor I/O from KConfig to work!
0046     KF6::GuiAddons # KColorScheme uses KColorUtils
0047     KF6::I18n # For action and widget texts
0048 )
0049
0050 ecm_generate_headers(KColorScheme_HEADERS
0051   HEADER_NAMES
0052   KColorScheme
0053   KColorSchemeManager
0054   KColorSchemeModel
0055   KStatefulBrush
0056
0057   REQUIRED_HEADERS KColorScheme_HEADERS
0058 )
0059
0060 install(TARGETS KF6ColorScheme EXPORT KF6ColorSchemeTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0061
0062 install(FILES
0063   ${CMAKE_CURRENT_BINARY_DIR}/kcolorscheme_export.h
0064   ${KColorScheme_HEADERS}
0065   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KColorScheme COMPONENT Devel
0066 )
0067
0068 ecm_qt_install_logging_categories(
0069     EXPORT KCOLORSCHEME
0070     FILE kcolorscheme.categories
0071     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0072 )
0073
0074
0075 if(BUILD_QCH)
0076     ecm_add_qch(
0077         KF6ColorScheme_QCH
0078         NAME KColorScheme
0079         BASE_NAME KF6ColorScheme
0080         VERSION ${KF_VERSION}
0081         ORG_DOMAIN org.kde
0082         SOURCES # using only public headers, to cover only public API
0083             ${KColorScheme_HEADERS}
0084         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0085         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0086         LINK_QCHS
0087             KF6GuiAddons_QCH
0088         INCLUDE_DIRS
0089             ${CMAKE_CURRENT_BINARY_DIR}
0090         BLANK_MACROS
0091             KCOLORSCHEME_EXPORT
0092             KCOLORSCHEME_DEPRECATED
0093             KCOLORSCHEME_DEPRECATED_EXPORT
0094             "KCOLORSCHEME_DEPRECATED_VERSION(x, y, t)"
0095             "KCOLORSCHEME_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0096             "KCOLORSCHEME_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0097             "KCOLORSCHEME_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0098         PREDEFINED_MACROS
0099             "KCOLORSCHEME_ENABLE_DEPRECATED_SINCE(x, y)=1"
0100             "KCOLORSCHEME_BUILD_DEPRECATED_SINCE(x, y)=1"
0101         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0102         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0103         COMPONENT Devel
0104     )
0105 endif()
0106