frameworks/kcolorscheme/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2023 David Redondo <kde@david-redondo.de>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 cmake_minimum_required(VERSION 3.16)
0005
0006 set(KF_VERSION "6.0.0") # handled by release scripts
0007 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0008 project(KColorScheme VERSION ${KF_VERSION})
0009
0010 include(FeatureSummary)
0011 find_package(ECM 5.249.0  NO_MODULE)
0012 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0013 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0014
0015 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0016
0017 include(KDEInstallDirs)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019 include(KDECMakeSettings)
0020 include(KDEGitCommitHooks)
0021
0022 include(ECMGenerateExportHeader)
0023 include(ECMSetupVersion)
0024 include(ECMGenerateHeaders)
0025 include(ECMAddQch)
0026 include(ECMQtDeclareLoggingCategory)
0027 include(ECMDeprecationSettings)
0028 include(CMakeDependentOption)
0029
0030 set(REQUIRED_QT_VERSION 6.5.0)
0031 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Gui)
0032
0033 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0034
0035 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0036 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0037
0038
0039 set(kcolorscheme_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kcolorscheme_version.h")
0040 ecm_setup_version(PROJECT VARIABLE_PREFIX KCOLORSCHEME
0041                         VERSION_HEADER "${kcolorscheme_version_header}"
0042                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ColorSchemeConfigVersion.cmake"
0043                         SOVERSION 6)
0044
0045 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0046 find_package(KF6GuiAddons ${KF_DEP_VERSION} REQUIRED)
0047 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0048
0049 ecm_set_disabled_deprecation_versions(
0050     QT 6.5.0
0051     KF 5.102.0
0052 )
0053
0054 add_definitions(-DTRANSLATION_DOMAIN=\"kcolorscheme6\")
0055 ki18n_install(po)
0056
0057 add_subdirectory(src)
0058 if(BUILD_TESTING)
0059     add_subdirectory(autotests)
0060 endif()
0061
0062 # create a Config.cmake and a ConfigVersion.cmake file and install them
0063 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ColorScheme")
0064
0065 if(BUILD_QCH)
0066     ecm_install_qch_export(
0067         TARGETS KF6ColorScheme_QCH
0068         FILE KF6ColorSchemeQchTargets.cmake
0069         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0070         COMPONENT Devel
0071     )
0072     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ColorSchemeQchTargets.cmake\")")
0073 endif()
0074
0075 include(CMakePackageConfigHelpers)
0076
0077 configure_package_config_file(
0078   "${CMAKE_CURRENT_SOURCE_DIR}/KF6ColorSchemeConfig.cmake.in"
0079   "${CMAKE_CURRENT_BINARY_DIR}/KF6ColorSchemeConfig.cmake"
0080   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0081 )
0082
0083 install(FILES
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF6ColorSchemeConfig.cmake"
0085   "${CMAKE_CURRENT_BINARY_DIR}/KF6ColorSchemeConfigVersion.cmake"
0086   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0087   COMPONENT Devel
0088 )
0089
0090 install(EXPORT KF6ColorSchemeTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ColorSchemeTargets.cmake NAMESPACE KF6::)
0091
0092 install(FILES
0093   ${kcolorscheme_version_header}
0094   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KColorScheme COMPONENT Devel
0095 )
0096
0097 include(ECMFeatureSummary)
0098 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0099
0100 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)