src/core/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2023 Alexander Lohnau <alexander.lohnau@gmx.de>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_library(KF6KCMUtilsCore)
0005
0006 set_target_properties(KF6KCMUtilsCore PROPERTIES
0007     VERSION     ${KCMUTILS_VERSION}
0008     SOVERSION   ${KCMUTILS_SOVERSION}
0009     EXPORT_NAME KCMUtilsCore
0010 )
0011
0012 ecm_qt_declare_logging_category(KF6KCMUtilsCore
0013     HEADER kcmutilscore_debug.h
0014     IDENTIFIER KCMUTILS_CORE_LOG
0015     CATEGORY_NAME kf.kcmutils.core
0016     DESCRIPTION "KCMUtilsCore"
0017     EXPORT KCMUTILS_CORE
0018 )
0019 ecm_generate_export_header(KF6KCMUtilsCore
0020     BASE_NAME KCMUtilsCore
0021     GROUP_BASE_NAME KF
0022     VERSION ${KF_VERSION}
0023     USE_VERSION_HEADER
0024     VERSION_BASE_NAME KCMUtils
0025     DEPRECATED_BASE_VERSION 0
0026 )
0027 target_include_directories(KF6KCMUtilsCore PUBLIC
0028     "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/..>" # module version header
0029 )
0030 target_include_directories(KF6KCMUtilsCore INTERFACE
0031     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCMUtilsCore>"
0032     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCMUtils>" # module version header
0033 )
0034
0035 target_sources(KF6KCMUtilsCore PRIVATE
0036     kpluginmodel.cpp
0037     kabstractconfigmodule.cpp
0038     kcmoduledata.cpp
0039     kcmoduledata.h
0040 )
0041 target_link_libraries(KF6KCMUtilsCore
0042   PUBLIC
0043     KF6::CoreAddons
0044   PRIVATE
0045     KF6::ConfigCore
0046     KF6::ItemViews
0047 )
0048
0049 ecm_generate_headers(KCMUtilsCore_HEADERS
0050   HEADER_NAMES
0051   KPluginModel
0052   KAbstractConfigModule
0053   KCModuleData
0054
0055   REQUIRED_HEADERS KCMUtilsCore_HEADERS
0056 )
0057 install(FILES
0058   ${CMAKE_CURRENT_BINARY_DIR}/kcmutilscore_export.h
0059   ${KCMUtilsCore_HEADERS}
0060   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCMUtilsCore COMPONENT Devel
0061 )
0062
0063 install(TARGETS KF6KCMUtilsCore EXPORT KF6KCMUtilsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0064
0065 add_library(kcmutils_proxy_model STATIC kpluginproxymodel.cpp)
0066 # Needed to link this static lib to shared libs
0067 set_property(TARGET kcmutils_proxy_model PROPERTY POSITION_INDEPENDENT_CODE ON)
0068 target_link_libraries(kcmutils_proxy_model PUBLIC KF6KCMUtilsCore KF6::ItemViews)
0069
0070 if(NOT BUILD_SHARED_LIBS)
0071   install(TARGETS kcmutils_proxy_model EXPORT KF6KCMUtilsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0072 endif()