src/core/CMakeLists.txt

0001 add_library(KF5KCMUtilsCore)
0002
0003 ecm_qt_declare_logging_category(KF5KCMUtilsCore
0004     HEADER kcmutilscore_debug.h
0005     IDENTIFIER KCMUTILS_CORE_LOG
0006     CATEGORY_NAME kf.kcmutils.core
0007     DESCRIPTION "KCMUtilsCore"
0008     EXPORT KCMUTILS_CORE
0009 )
0010 ecm_generate_export_header(KF5KCMUtilsCore
0011     BASE_NAME KCMUtilsCore
0012     GROUP_BASE_NAME KF
0013     VERSION ${KF_VERSION}
0014     DEPRECATED_BASE_VERSION 0
0015 )
0016 target_include_directories(KF5KCMUtilsCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCMUtilsCore>")
0017
0018 target_sources(KF5KCMUtilsCore PRIVATE kpluginmodel.cpp)
0019 target_link_libraries(KF5KCMUtilsCore
0020   PUBLIC
0021     KF5::CoreAddons
0022   PRIVATE
0023     KF5::ConfigCore
0024     KF5::Service # KServiceTypeTrader compat code path
0025     KF5::ItemViews
0026 )
0027
0028 set_target_properties(KF5KCMUtilsCore PROPERTIES
0029                       VERSION ${KCMUTILS_VERSION}
0030                       SOVERSION ${KCMUTILS_SOVERSION}
0031                       EXPORT_NAME KCMUtilsCore)
0032 ecm_generate_headers(KCMUtilsCore_HEADERS
0033   HEADER_NAMES
0034   KPluginModel
0035
0036   REQUIRED_HEADERS KCMUtilsCore_HEADERS
0037 )
0038 install(FILES
0039   ${CMAKE_CURRENT_BINARY_DIR}/kcmutilscore_export.h
0040   ${KCMUtilsCore_HEADERS}
0041   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCMUtilsCore COMPONENT Devel
0042 )
0043
0044 install(TARGETS KF5KCMUtilsCore EXPORT KF5KCMUtilsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0045
0046 add_library(kcmutils_proxy_model STATIC kpluginproxymodel.cpp)
0047 # Needed to link this static lib to shared libs
0048 set_property(TARGET kcmutils_proxy_model PROPERTY POSITION_INDEPENDENT_CODE ON)
0049 target_link_libraries(kcmutils_proxy_model PUBLIC KF5KCMUtilsCore KF5::ItemViews)
0050
0051 if(NOT BUILD_SHARED_LIBS)
0052   install(TARGETS kcmutils_proxy_model EXPORT KF5KCMUtilsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0053 endif()