kcalendarcore/src/CMakeLists.txt

0001 add_library(KF5CalendarCore)
0002 add_library(KF5::CalendarCore ALIAS KF5CalendarCore)
0003
0004 set_target_properties(KF5CalendarCore PROPERTIES
0005     VERSION     ${KCALENDARCORE_VERSION}
0006     SOVERSION   ${KCALENDARCORE_SOVERSION}
0007     EXPORT_NAME CalendarCore
0008 )
0009
0010 target_sources(KF5CalendarCore PRIVATE
0011     alarm.cpp
0012     alarm.h
0013     attachment.cpp
0014     attachment.h
0015     attendee.cpp
0016     attendee.h
0017     calendar.cpp
0018     calendar.h
0019     calendar_p.h
0020     calendarplugin.cpp
0021     calendarplugin.h
0022     calendarpluginloader.cpp
0023     calendarpluginloader.h
0024     calfilter.cpp
0025     calfilter.h
0026     calformat.cpp
0027     calformat.h
0028     calstorage.cpp
0029     calstorage.h
0030     compat.cpp
0031     compat_p.h
0032     conference.cpp
0033     conference.h
0034     customproperties.cpp
0035     customproperties.h
0036     duration.cpp
0037     duration.h
0038     event.cpp
0039     event.h
0040     exceptions.cpp
0041     exceptions.h
0042     filestorage.cpp
0043     filestorage.h
0044     freebusycache.cpp
0045     freebusycache.h
0046     freebusy.cpp
0047     freebusy.h
0048     freebusyperiod.cpp
0049     freebusyperiod.h
0050     icalformat.cpp
0051     icalformat.h
0052     icalformat_p.cpp
0053     icalformat_p.h
0054     icaltimezones.cpp
0055     icaltimezones_p.h
0056     incidencebase.cpp
0057     incidencebase.h
0058     incidencebase_p.h
0059     incidence.cpp
0060     incidence.h
0061     incidence_p.h
0062     journal.cpp
0063     journal.h
0064     memorycalendar.cpp
0065     memorycalendar.h
0066     occurrenceiterator.cpp
0067     occurrenceiterator.h
0068     period.cpp
0069     period.h
0070     person.cpp
0071     person.h
0072     person_p.h
0073     recurrence.cpp
0074     recurrence.h
0075     recurrencehelper_p.h
0076     recurrencerule.cpp
0077     recurrencerule.h
0078     schedulemessage.cpp
0079     schedulemessage.h
0080     sorting.cpp
0081     sorting.h
0082     todo.cpp
0083     todo.h
0084     utils.cpp
0085     utils_p.h
0086     vcalformat.cpp
0087     vcalformat.h
0088     visitor.cpp
0089     visitor.h
0090
0091 )
0092 ecm_qt_declare_logging_category(KF5CalendarCore
0093     HEADER kcalendarcore_debug.h
0094     IDENTIFIER KCALCORE_LOG
0095     CATEGORY_NAME kf.calendarcore
0096     OLD_CATEGORY_NAMES log_kcalcore org.kde.pim.kcalcore
0097     DESCRIPTION "KCalendarCore"
0098     EXPORT KCALENDARCORE
0099 )
0100
0101 ecm_generate_export_header(KF5CalendarCore
0102     BASE_NAME kcalendarcore
0103     GROUP_BASE_NAME KF
0104     VERSION ${KF_VERSION}
0105     DEPRECATED_BASE_VERSION 0
0106     DEPRECATION_VERSIONS 5.64 5.89 5.91 5.95 5.96 5.97 5.106
0107     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0108 )
0109
0110
0111 # backward compatibility with the old name
0112 if (NOT KCALENDARCORE_NO_DEPRECATED_NAMESPACE)
0113     target_compile_definitions(KF5CalendarCore INTERFACE "-DKCalCore=KCalendarCore")
0114 endif()
0115
0116 target_include_directories(KF5CalendarCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore>")
0117 target_include_directories(KF5CalendarCore PUBLIC "$<BUILD_INTERFACE:${KCalendarCore_SOURCE_DIR}/src;${KCalendarCore_BINARY_DIR}/src>")
0118
0119 target_link_libraries(KF5CalendarCore
0120 PUBLIC
0121     Qt${QT_MAJOR_VERSION}::Core
0122     Qt${QT_MAJOR_VERSION}::Gui
0123 PRIVATE
0124     LibIcal
0125 )
0126
0127 install(TARGETS KF5CalendarCore EXPORT KF5CalendarCoreTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0128
0129 ########### Generate Headers ###############
0130 set(kcalendarcore_headers
0131   Alarm
0132   Attachment
0133   Attendee
0134   CalFilter
0135   CalFormat
0136   CalStorage
0137   Calendar
0138   CalendarPlugin
0139   CalendarPluginLoader
0140   Conference
0141   CustomProperties
0142   Duration
0143   Event
0144   Exceptions
0145   FileStorage
0146   FreeBusy
0147   FreeBusyCache
0148   FreeBusyPeriod
0149   ICalFormat
0150   Incidence
0151   IncidenceBase
0152   Journal
0153   MemoryCalendar
0154   OccurrenceIterator
0155   Period
0156   Person
0157   Recurrence
0158   RecurrenceRule
0159   ScheduleMessage
0160   Sorting
0161   Todo
0162   VCalFormat
0163   Visitor
0164 )
0165
0166 ecm_generate_headers(KCalendarCore_CamelCase_HEADERS
0167   HEADER_NAMES
0168     ${kcalendarcore_headers}
0169   PREFIX KCalendarCore
0170   REQUIRED_HEADERS KCalendarCore_HEADERS
0171 )
0172
0173 if (NOT KCALENDARCORE_NO_DEPRECATED_NAMESPACE)
0174   ecm_generate_headers(KCalCore_CamelCase_HEADERS
0175     HEADER_NAMES
0176       ${kcalendarcore_headers}
0177     PREFIX KCalCore
0178     REQUIRED_HEADERS KCalCore_HEADERS
0179   )
0180 endif()
0181
0182 ########### install files ###############
0183
0184 install(FILES
0185   ${CMAKE_CURRENT_BINARY_DIR}/kcalendarcore_export.h
0186   ${KCalendarCore_HEADERS}
0187   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore/kcalendarcore
0188   COMPONENT Devel
0189 )
0190
0191 install(FILES
0192   ${KCalendarCore_CamelCase_HEADERS}
0193   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore/KCalendarCore
0194   COMPONENT Devel
0195 )
0196
0197 if (NOT KCALENDARCORE_NO_DEPRECATED_NAMESPACE)
0198   install(FILES
0199     ${CMAKE_CURRENT_BINARY_DIR}/kcalendarcore_export.h
0200     ${KCalCore_HEADERS}
0201     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore/kcalcore
0202     COMPONENT Devel
0203   )
0204
0205   install(FILES
0206     ${KCalCore_CamelCase_HEADERS}
0207     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore/KCalCore
0208     COMPONENT Devel
0209   )
0210 endif()
0211
0212 ecm_qt_install_logging_categories(
0213     EXPORT KCALENDARCORE
0214     FILE kcalendarcore.categories
0215     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0216 )
0217
0218 ecm_generate_pri_file(BASE_NAME KCalendarCore LIB_NAME KF5CalendarCore DEPS "Core" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KCalendarCore/KCalendarCore)
0219 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0220
0221 if(BUILD_QCH)
0222     ecm_add_qch(
0223         KF5CalendarCore_QCH
0224         NAME KCalendarCore
0225         BASE_NAME KF5CalendarCore
0226         VERSION ${KCalendarCore_VERSION}
0227         ORG_DOMAIN org.kde
0228         SOURCES # using only public headers, to cover only public API
0229             ${KCalendarCore_HEADERS}
0230         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0231         LINK_QCHS
0232             Qt5Core_QCH
0233         INCLUDE_DIRS
0234             ${CMAKE_CURRENT_BINARY_DIR}
0235         BLANK_MACROS
0236             KCALENDARCORE_EXPORT
0237             "KCALENDARCORE_DEPRECATED_VERSION(x, y, t)"
0238         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0239         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0240         COMPONENT Devel
0241     )
0242 endif()