src/widgets/CMakeLists.txt

0001 add_library(KF6BookmarksWidgets)
0002 add_library(KF6::BookmarksWidgets ALIAS KF6BookmarksWidgets)
0003
0004 set_target_properties(KF6BookmarksWidgets PROPERTIES
0005     VERSION     ${KBOOKMARKS_VERSION}
0006     SOVERSION   ${KBOOKMARKS_SOVERSION}
0007     EXPORT_NAME BookmarksWidgets
0008 )
0009
0010 ecm_create_qm_loader(KF6BookmarksWidgets kbookmarkswidgets6_qt)
0011
0012 target_sources(KF6BookmarksWidgets PRIVATE
0013     kbookmarkactionmenu.cpp
0014     kbookmarkactionmenu.h
0015     kbookmarkcontextmenu.cpp
0016     kbookmarkcontextmenu.h
0017     kbookmarkdialog.cpp
0018     kbookmarkdialog.h
0019     kbookmarkdialog_p.h
0020     kbookmarkmenu.cpp
0021     kbookmarkmenu.h
0022     kbookmarkmenu_p.h
0023 )
0024
0025 ecm_qt_declare_logging_category(KF6BookmarksWidgets
0026     HEADER kbookmarkswidgets_debug.h
0027     IDENTIFIER KBOOKMARKSWIDGETS_LOG
0028     CATEGORY_NAME kf.bookmarks.widgets
0029     DESCRIPTION "KBookmarks Widgets"
0030     EXPORT KBOOKMARKSWIDGETS
0031 )
0032
0033 ecm_generate_export_header(KF6BookmarksWidgets
0034     BASE_NAME KBookmarksWidgets
0035     GROUP_BASE_NAME KF
0036     VERSION ${KF_VERSION}
0037     USE_VERSION_HEADER kbookmarks_version.h
0038     DEPRECATED_BASE_VERSION 0
0039     DEPRECATION_VERSIONS
0040     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0041 )
0042
0043 target_include_directories(KF6BookmarksWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarksWidgets>")
0044
0045 target_link_libraries(KF6BookmarksWidgets PUBLIC Qt6::Widgets KF6::WidgetsAddons)
0046 target_link_libraries(KF6BookmarksWidgets PRIVATE
0047     KF6::ConfigWidgets # for KStandardAction
0048     KF6::Bookmarks
0049 )
0050
0051 ecm_generate_headers(KBookmarksWidgets_HEADERS
0052   HEADER_NAMES
0053   KBookmarkActionMenu
0054   KBookmarkContextMenu
0055   KBookmarkMenu
0056   KBookmarkDialog
0057
0058   REQUIRED_HEADERS KBookmarksWidgets_HEADERS
0059 )
0060
0061 install(TARGETS KF6BookmarksWidgets EXPORT KF6BookmarksTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0062
0063 install(FILES
0064   ${CMAKE_CURRENT_BINARY_DIR}/kbookmarkswidgets_export.h
0065   ${KBookmarksWidgets_HEADERS}
0066   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarksWidgets COMPONENT Devel
0067 )
0068
0069 ecm_qt_install_logging_categories(
0070     EXPORT KBOOKMARKSWIDGETS
0071     FILE kbookmarkswidgets.categories
0072     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0073 )
0074
0075 if(BUILD_QCH)
0076     ecm_add_qch(
0077         KF6BookmarksWidgets_QCH
0078         NAME KBookmarksWidgets
0079         BASE_NAME KF6BookmarksWidgets
0080         VERSION ${KF_VERSION}
0081         ORG_DOMAIN org.kde
0082         SOURCES # using only public headers, to cover only public API
0083             ${KBookmarksWidgets_HEADERS}
0084         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0085         LINK_QCHS
0086             Qt6Widgets_QCH
0087             Qt6Xml_QCH
0088             KF6WidgetsAddons_QCH
0089         INCLUDE_DIRS
0090             ${CMAKE_CURRENT_BINARY_DIR}
0091         BLANK_MACROS
0092             KBOOKMARKSWIDGETS_EXPORT
0093             KBOOKMARKSWIDGETS_DEPRECATED
0094             KBOOKMARKSWIDGETS_DEPRECATED_EXPORT
0095             "KBOOKMARKS_DEPRECATED_VERSION(x, y, t)"
0096         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0097         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0098         COMPONENT Devel
0099     )
0100 endif()