frameworks/kbookmarks/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KBookmarks VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015 include(KDEInstallDirs)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEGitCommitHooks)
0019 include(ECMQtDeclareLoggingCategory)
0020 include(ECMDeprecationSettings)
0021
0022 include(ECMGenerateExportHeader)
0023 include(ECMSetupVersion)
0024 include(ECMGenerateHeaders)
0025
0026 include(ECMAddQch)
0027 include(ECMPoQmTools)
0028
0029 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0030
0031 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0032 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0033
0034 set(kbookmarks_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kbookmarks_version.h")
0035 ecm_setup_version(PROJECT
0036                   VARIABLE_PREFIX KBOOKMARKS
0037                   VERSION_HEADER "${kbookmarks_version_header}"
0038                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6BookmarksConfigVersion.cmake"
0039                   SOVERSION 6)
0040
0041 # Dependencies
0042 set(REQUIRED_QT_VERSION 6.5.0)
0043
0044 find_package(Qt6 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED Widgets Xml)
0045
0046 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0047 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0048 find_package(KF6ConfigWidgets ${KF_DEP_VERSION} REQUIRED)
0049 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0050
0051 ecm_install_po_files_as_qm(poqm)
0052 ecm_set_disabled_deprecation_versions(
0053     QT 6.5
0054     KF 5.240
0055 )
0056
0057
0058 add_subdirectory(src)
0059 if (BUILD_TESTING)
0060     add_subdirectory(tests)
0061     add_subdirectory(autotests)
0062 endif()
0063
0064 # create a Config.cmake and a ConfigVersion.cmake file and install them
0065 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Bookmarks")
0066
0067 if (BUILD_QCH)
0068     ecm_install_qch_export(
0069         TARGETS KF6Bookmarks_QCH
0070         FILE KF6BookmarksQchTargets.cmake
0071         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0072         COMPONENT Devel
0073     )
0074     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6BookmarksQchTargets.cmake\")")
0075 endif()
0076
0077 include(CMakePackageConfigHelpers)
0078
0079 configure_package_config_file(
0080   "${CMAKE_CURRENT_SOURCE_DIR}/KF6BookmarksConfig.cmake.in"
0081   "${CMAKE_CURRENT_BINARY_DIR}/KF6BookmarksConfig.cmake"
0082   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0083 )
0084
0085 install(FILES
0086   "${CMAKE_CURRENT_BINARY_DIR}/KF6BookmarksConfig.cmake"
0087   "${CMAKE_CURRENT_BINARY_DIR}/KF6BookmarksConfigVersion.cmake"
0088   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089   COMPONENT Devel
0090 )
0091
0092 install(EXPORT KF6BookmarksTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6BookmarksTargets.cmake NAMESPACE KF6:: )
0093
0094 install(FILES
0095    ${kbookmarks_version_header}
0096   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks COMPONENT Devel
0097 )
0098
0099 include(ECMFeatureSummary)
0100 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0101
0102 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)