frameworks/karchive/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 project(KArchive VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.115.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018
0019 include(ECMGenerateExportHeader)
0020
0021 set(REQUIRED_QT_VERSION 5.15.2)
0022 find_package(Qt${QT_MAJOR_VERSION}Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0023
0024 find_package(ZLIB)
0025 set_package_properties(ZLIB PROPERTIES
0026     URL "https://www.zlib.net"
0027     DESCRIPTION "Support for gzip compressed files and data streams"
0028     TYPE REQUIRED
0029     PURPOSE "Support for gzip compressed files and data streams"
0030 )
0031
0032 find_package(BZip2)
0033 set_package_properties(BZip2 PROPERTIES
0034     URL "https://sourceware.org/bzip2/"
0035     DESCRIPTION "Support for BZip2 compressed files and data streams"
0036     TYPE RECOMMENDED
0037     PURPOSE "Support for BZip2 compressed files and data streams"
0038 )
0039
0040 find_package(LibLZMA)
0041 set_package_properties(LibLZMA PROPERTIES
0042     URL "https://tukaani.org/xz/"
0043     DESCRIPTION "Support for xz compressed files and data streams"
0044     PURPOSE "Support for xz compressed files and data streams"
0045 )
0046
0047 find_package(PkgConfig)
0048 if (PkgConfig_FOUND)
0049     pkg_check_modules(LibZstd IMPORTED_TARGET "libzstd")
0050 endif()
0051 add_feature_info(LibZstd LibZstd_FOUND
0052                 "Support for zstd compressed files and data streams"
0053 )
0054
0055 include(ECMSetupVersion)
0056 include(ECMGenerateHeaders)
0057 include(ECMQtDeclareLoggingCategory)
0058 include(ECMAddQch)
0059 include(ECMDeprecationSettings)
0060 include(ECMPoQmTools)
0061
0062 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0063
0064 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0065 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0066
0067 ecm_setup_version(PROJECT
0068     VARIABLE_PREFIX KARCHIVE
0069     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/karchive_version.h"
0070     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ArchiveConfigVersion.cmake"
0071     SOVERSION 5)
0072
0073 ecm_set_disabled_deprecation_versions(
0074     QT 5.15.2
0075 )
0076
0077
0078 add_subdirectory(src)
0079 if (BUILD_TESTING)
0080     add_subdirectory(autotests)
0081     add_subdirectory(tests)
0082 endif()
0083
0084 ecm_install_po_files_as_qm(poqm)
0085
0086 # create a Config.cmake and a ConfigVersion.cmake file and install them
0087 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Archive")
0088
0089 if (BUILD_QCH)
0090     ecm_install_qch_export(
0091         TARGETS KF5Archive_QCH
0092         FILE KF5ArchiveQchTargets.cmake
0093         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0094         COMPONENT Devel
0095     )
0096     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ArchiveQchTargets.cmake\")")
0097 endif()
0098
0099 include(CMakePackageConfigHelpers)
0100
0101 configure_package_config_file(
0102     "${CMAKE_CURRENT_SOURCE_DIR}/KF5ArchiveConfig.cmake.in"
0103     "${CMAKE_CURRENT_BINARY_DIR}/KF5ArchiveConfig.cmake"
0104     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0105 )
0106
0107 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/karchive_version.h
0108         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KArchive
0109         COMPONENT Devel)
0110
0111 install(FILES
0112             "${CMAKE_CURRENT_BINARY_DIR}/KF5ArchiveConfig.cmake"
0113             "${CMAKE_CURRENT_BINARY_DIR}/KF5ArchiveConfigVersion.cmake"
0114         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0115         COMPONENT Devel)
0116
0117 install(EXPORT KF5ArchiveTargets
0118         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0119         FILE KF5ArchiveTargets.cmake
0120         NAMESPACE KF5::)
0121
0122 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0123
0124 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)