frameworks/kactivities-stats/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002
0003 cmake_minimum_required(VERSION 3.16)
0004
0005 set(KF_VERSION "5.107.0") # handled by release scripts
0006 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0007 project (KActivitiesStats VERSION ${KF_VERSION})
0008
0009 set (REQUIRED_QT_VERSION 5.15.2)
0010
0011 # We don't build in-source
0012 if ("${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_BINARY_DIR}")
0013    message (
0014       FATAL_ERROR
0015       "kactivities-stats require an out of source build. Please create a separate build directory and run 'cmake path_to_kactivities-stats [options]' there."
0016    )
0017 endif ()
0018
0019 set (KASTATS_CURRENT_ROOT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
0020
0021 # Extra CMake stuff
0022 include (FeatureSummary)
0023 find_package (ECM 5.106.0  NO_MODULE)
0024 set_package_properties (ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0025 feature_summary (WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0026
0027 set (CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0028
0029 include (KDEInstallDirs)
0030 include (KDECMakeSettings)
0031 include(KDEGitCommitHooks)
0032 include (KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0033 include (GenerateExportHeader)
0034 include (ECMGenerateHeaders)
0035 include (ECMGeneratePkgConfigFile)
0036 include (ECMAddQch)
0037 include (ECMQtDeclareLoggingCategory)
0038 include(ECMDeprecationSettings)
0039
0040 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0041 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0042
0043 # Qt
0044 set (CMAKE_AUTOMOC ON)
0045 find_package (Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED COMPONENTS Core DBus Sql)
0046
0047 # KDE Frameworks
0048 # find_package (KF5DBusAddons ${KF_DEP_VERSION} CONFIG REQUIRED)
0049 # find_package (KF5I18n ${KF_DEP_VERSION} CONFIG REQUIRED)
0050 find_package (KF5Config ${KF_DEP_VERSION} CONFIG REQUIRED)
0051 find_package (KF5Activities ${KF_DEP_VERSION} CONFIG REQUIRED)
0052 find_package(Threads REQUIRED)
0053
0054 # Basic includes
0055 include (CPack)
0056
0057 include (CMakePackageConfigHelpers)
0058 include (ECMSetupVersion)
0059
0060
0061 # Adding local CMake modules
0062 set (
0063    CMAKE_MODULE_PATH
0064    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules
0065    ${CMAKE_MODULE_PATH}
0066    )
0067
0068 # add_definitions (-DTRANSLATION_DOMAIN=\"kactivitiesstats5\")
0069 # ki18n_install (po)
0070
0071 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
0072    set(CMAKE_CXX_VISIBILITY_PRESET default)
0073    set(CMAKE_VISIBILITY_INLINES_HIDDEN 0)
0074 endif ()
0075
0076 # libKActivitiesStats
0077
0078 ecm_setup_version (
0079    PROJECT
0080    VARIABLE_PREFIX KACTIVITIESSTATS
0081    VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kactivitiesstats_version.h"
0082    PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ActivitiesStatsConfigVersion.cmake"
0083    SOVERSION 1
0084    )
0085 ecm_set_disabled_deprecation_versions(
0086     QT 5.15.2
0087     KF 5.95.0
0088 )
0089
0090
0091 add_subdirectory (src)
0092 if(BUILD_TESTING)
0093   set(Boost_NO_BOOST_CMAKE ON)
0094   find_package (Boost 1.49)
0095   if (Boost_FOUND)
0096     add_subdirectory (autotests)
0097   endif ()
0098   add_subdirectory (tests)
0099 endif (BUILD_TESTING)
0100
0101 set (CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5ActivitiesStats")
0102
0103 if (BUILD_QCH)
0104     ecm_install_qch_export(
0105         TARGETS KF5ActivitiesStats_QCH
0106         FILE KF5ActivitiesStatsLibraryQchTargets.cmake
0107         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0108         COMPONENT Devel
0109     )
0110     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ActivitiesStatsLibraryQchTargets.cmake\")")
0111 endif()
0112
0113 install (
0114    EXPORT KF5ActivitiesStatsLibraryTargets
0115    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0116    FILE KF5ActivitiesStatsLibraryTargets.cmake
0117    NAMESPACE KF5::
0118    )
0119
0120 configure_package_config_file (
0121    "${CMAKE_CURRENT_SOURCE_DIR}/KF5ActivitiesStatsConfig.cmake.in"
0122    "${CMAKE_CURRENT_BINARY_DIR}/KF5ActivitiesStatsConfig.cmake"
0123    INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0124    )
0125
0126 install (
0127    FILES "${CMAKE_CURRENT_BINARY_DIR}/KF5ActivitiesStatsConfig.cmake"
0128          "${CMAKE_CURRENT_BINARY_DIR}/KF5ActivitiesStatsConfigVersion.cmake"
0129    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0130    COMPONENT Devel
0131    )
0132
0133 install (
0134    FILES ${CMAKE_CURRENT_BINARY_DIR}/kactivitiesstats_version.h
0135    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats COMPONENT Devel
0136    )
0137
0138 # Write out the features
0139 feature_summary (WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0140
0141 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)