src/kstyle/CMakeLists.txt

0001 # create a Config.cmake and a ConfigVersion.cmake file and install them
0002 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Style")
0003
0004 add_library(KF6Style kstyle.cpp)
0005 add_library(KF6::Style ALIAS KF6Style)
0006
0007 set_target_properties(KF6Style PROPERTIES
0008     VERSION     ${FRAMEWORKINTEGRATION_VERSION}
0009     SOVERSION   ${FRAMEWORKINTEGRATION_SOVERSION}
0010     EXPORT_NAME Style
0011 )
0012
0013 ecm_generate_export_header(KF6Style
0014     BASE_NAME KStyle
0015     GROUP_BASE_NAME KF
0016     VERSION ${KF_VERSION}
0017     USE_VERSION_HEADER
0018     VERSION_BASE_NAME FrameworkIntegration
0019     DEPRECATED_BASE_VERSION 0
0020 )
0021
0022 target_include_directories(KF6Style
0023     INTERFACE
0024         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/FrameworkIntegration>" # version header
0025         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KStyle>"
0026     PUBLIC
0027         "$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}>" # version header
0028 )
0029
0030 target_link_libraries(KF6Style
0031     PUBLIC
0032         Qt6::Widgets
0033     PRIVATE
0034         KF6::WidgetsAddons
0035         KF6::ColorScheme
0036         KF6::IconThemes
0037 )
0038
0039 ecm_generate_headers(KStyle_HEADERS
0040   HEADER_NAMES
0041     KStyle
0042   REQUIRED_HEADERS KStyle_HEADERS
0043 )
0044
0045 install(TARGETS KF6Style
0046         EXPORT KF6FrameworkIntegrationTargets
0047         ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0048
0049 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kstyle_export.h
0050               ${KStyle_HEADERS}
0051         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KStyle
0052         COMPONENT Devel)
0053