frameworks/frameworkintegration/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(FrameworkIntegration VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012
0013 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0014
0015
0016 include(ECMGenerateExportHeader)
0017 include(CMakePackageConfigHelpers)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020
0021 include(KDEInstallDirs)
0022 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0023 include(KDECMakeSettings)
0024 include(KDEGitCommitHooks)
0025 include(ECMDeprecationSettings)
0026
0027 set(REQUIRED_QT_VERSION 6.5.0)
0028 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Gui Widgets)
0029
0030
0031 ecm_setup_version(PROJECT VARIABLE_PREFIX FRAMEWORKINTEGRATION
0032                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/frameworkintegration_version.h"
0033                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6FrameworkIntegrationConfigVersion.cmake"
0034                   SOVERSION 6)
0035
0036 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0037 find_package(KF6ColorScheme ${KF_DEP_VERSION} REQUIRED)
0038 find_package(KF6IconThemes ${KF_DEP_VERSION} REQUIRED)
0039 find_package(KF6Notifications ${KF_DEP_VERSION} REQUIRED)
0040 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0041
0042
0043 option(BUILD_KPACKAGE_INSTALL_HANDLERS "Build the KPackage install handler binaries (recommended)" ON)
0044 if (BUILD_KPACKAGE_INSTALL_HANDLERS)
0045    find_package(KF6NewStuffCore ${KF_DEP_VERSION} REQUIRED)
0046    find_package(KF6Package ${KF_DEP_VERSION} REQUIRED)
0047    find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0048
0049    find_package(packagekitqt6)
0050    find_package(AppStreamQt 1.0)
0051 endif()
0052
0053 ecm_set_disabled_deprecation_versions(
0054     QT 6.5.0
0055     KF 5.102
0056 )
0057
0058 add_subdirectory(src)
0059 if (BUILD_TESTING)
0060     add_subdirectory(autotests)
0061     add_subdirectory(tests)
0062 endif()
0063
0064 # create a Config.cmake and a ConfigVersion.cmake file and install them
0065 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6FrameworkIntegration")
0066
0067 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6FrameworkIntegrationConfig.cmake.in"
0068                               "${CMAKE_CURRENT_BINARY_DIR}/KF6FrameworkIntegrationConfig.cmake"
0069                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0070                               )
0071
0072 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF6FrameworkIntegrationConfig.cmake"
0073                "${CMAKE_CURRENT_BINARY_DIR}/KF6FrameworkIntegrationConfigVersion.cmake"
0074         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0075         COMPONENT Devel )
0076
0077 install(EXPORT KF6FrameworkIntegrationTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6FrameworkIntegrationTargets.cmake NAMESPACE KF6:: )
0078
0079 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/frameworkintegration_version.h
0080         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/FrameworkIntegration COMPONENT Devel)
0081
0082 install(FILES plasma_workspace.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})
0083
0084
0085 include(ECMFeatureSummary)
0086 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)
0087
0088 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)