ECMGenerateExportHeaderTest/consumer/testAPI_DISABLE_DEPRECATED_BEFORE_AND_AT.cmake

0001 function(generate_hex_number _var_name _version)
0002     set(_hexnumber 0)
0003
0004     set(version_regex "^([0-9]+)\\.([0-9]+)\\.([0-9]+)$")
0005     string(REGEX REPLACE ${version_regex} "\\1" _version_major "${_version}")
0006     string(REGEX REPLACE ${version_regex} "\\2" _version_minor "${_version}")
0007     string(REGEX REPLACE ${version_regex} "\\3" _version_patch "${_version}")
0008     set(_outputformat)
0009     set(_outputformat OUTPUT_FORMAT HEXADECIMAL)
0010     math(EXPR _hexnumber "${_version_major}*65536 + ${_version_minor}*256 + ${_version_patch}" ${_outputformat})
0011     set(${_var_name} ${_hexnumber} PARENT_SCOPE)
0012 endfunction()
0013
0014
0015 generate_hex_number(disable_deprecated_before_and_at_hexnumber ${LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT})
0016
0017 if(GROUP_MODE STREQUAL "GROUP_USE_GROUP")
0018     set(_deprecation_macros_base_name "LIBGROUP")
0019 else()
0020     set(_deprecation_macros_base_name "LIBRARY")
0021 endif()
0022
0023 function(testAPI code_var_name)
0024     set(options BUILD_TIME_ONLY_DISABLABLE NO_WARNING)
0025     set(oneValueArgs DEPRECATED_AT CXX_STANDARD)
0026     set(multiValueArgs)
0027     cmake_parse_arguments(ARGS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
0028
0029     if((NOT ARGS_DEPRECATED_AT) OR
0030        (ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT VERSION_GREATER DEPRECATED_EXCLUDED_BEFORE_AND_AT) OR
0031        (ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT))
0032        set(_build_result_expected TRUE)
0033     else()
0034        set(_build_result_expected FALSE)
0035     endif()
0036
0037     if (ARGS_CXX_STANDARD)
0038         if(MSVC)
0039             # C++11 is default for MSVC, no /std:c++11 flag available to set
0040             if (NOT ARGS_CXX_STANDARD STREQUAL "11")
0041                 set(std_flag  "/std:c++${ARGS_CXX_STANDARD}")
0042             endif()
0043         else()
0044             set(std_flag "-std=c++${ARGS_CXX_STANDARD}")
0045         endif()
0046     else()
0047         set(std_flag)
0048     endif()
0049
0050     set(CMAKE_REQUIRED_FLAGS "${std_flag}")
0051     set(CMAKE_REQUIRED_LIBRARIES library)
0052     set(CMAKE_REQUIRED_DEFINITIONS "-D${_deprecation_macros_base_name}_DISABLE_DEPRECATED_BEFORE_AND_AT=${disable_deprecated_before_and_at_hexnumber}")
0053
0054     set(_code "
0055 #include <library.hpp>
0056 int main(int, char**)
0057 {
0058     ${${code_var_name}}
0059 }
0060 ")
0061
0062     unset(_result CACHE) # clear out as check_cxx_source_compiles caches the result
0063     check_cxx_source_compiles("${_code}" _result)
0064
0065     assert_var_bool_value(_result ${_build_result_expected})
0066
0067     # check warning
0068     if(_build_result_expected)
0069         if(NOT ARGS_NO_WARNING AND
0070            ((ARGS_BUILD_TIME_ONLY_DISABLABLE) OR
0071             (NOT ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT AND
0072              ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT)))
0073             set(_dep_warning_as_error_result_expected FALSE)
0074         else()
0075             set(_dep_warning_as_error_result_expected TRUE)
0076         endif()
0077
0078         if(MSVC)
0079             # warning C4996 warns about deprecated declarations
0080             set(dep_warning_as_error_flag "-we4996")
0081         else()
0082             set(dep_warning_as_error_flag "-Werror=deprecated-declarations")
0083         endif()
0084
0085         set(CMAKE_REQUIRED_FLAGS "${std_flag} ${dep_warning_as_error_flag}")
0086         set(CMAKE_REQUIRED_DEFINITIONS) # unset LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT, as LIBRARY_DEPRECATED_WARNINGS_SINCE defaults to it
0087         unset(_dep_warning_result CACHE) # clear out as check_cxx_source_compiles caches the result
0088         check_cxx_source_compiles("${_code}" _dep_warning_result)
0089         assert_var_bool_value(_dep_warning_result ${_dep_warning_as_error_result_expected})
0090     endif()
0091 endfunction()