extra-cmake-modules/find-modules/FindIcoTool.cmake

0001 # SPDX-FileCopyrightText: 2017 Vincent Pinon <vpinon@kde.org>
0002 # SPDX-FileCopyrightText: 2014 Alex Merry <alex.merry@kde.org>
0003 #
0004 # SPDX-License-Identifier: BSD-3-Clause
0005
0006 #[=======================================================================[.rst:
0007 FindIcoTool
0008 -----------
0009
0010 Try to find icotool.
0011
0012 If the icotool executable is not in your PATH, you can provide
0013 an alternative name or full path location with the ``IcoTool_EXECUTABLE``
0014 variable.
0015
0016 This will define the following variables:
0017
0018 ``IcoTool_FOUND``
0019     True if icotool is available.
0020
0021 ``IcoTool_EXECUTABLE``
0022     The icotool executable.
0023
0024 If ``IcoTool_FOUND`` is TRUE, it will also define the following imported
0025 target:
0026
0027 ``IcoTool::IcoTool``
0028     The icotool executable.
0029
0030 Since 5.49.
0031 #]=======================================================================]
0032
0033 include(${CMAKE_CURRENT_LIST_DIR}/ECMFindModuleHelpersStub.cmake)
0034 ecm_find_package_version_check(IcoTool)
0035 find_program(IcoTool_EXECUTABLE NAMES icotool)
0036 include(FindPackageHandleStandardArgs)
0037 find_package_handle_standard_args(IcoTool
0038     FOUND_VAR
0039         IcoTool_FOUND
0040     REQUIRED_VARS
0041         IcoTool_EXECUTABLE
0042 )
0043 mark_as_advanced(IcoTool_EXECUTABLE)
0044
0045 if (IcoTool_FOUND)
0046     if (NOT TARGET IcoTool::IcoTool)
0047         add_executable(IcoTool::IcoTool IMPORTED)
0048         set_target_properties(IcoTool::IcoTool PROPERTIES
0049             IMPORTED_LOCATION "${IcoTool_EXECUTABLE}"
0050         )
0051     endif()
0052 endif()
0053
0054 include(FeatureSummary)
0055 set_package_properties(IcoTool PROPERTIES
0056     URL "https://www.nongnu.org/icoutils/"
0057     DESCRIPTION "Executable that converts a collection of PNG files into a Windows icon file"
0058 )