extra-cmake-modules/cmake/FindQCollectionGenerator.cmake

0001 # SPDX-FileCopyrightText: 2015 Alex Merry <alex.merry@kde.org>
0002 #
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 #[=======================================================================[.rst:
0006 FindQCollectionGenerator
0007 ------------------------
0008
0009 Try to find the Qt help collection generator.
0010
0011 This will define the following variables:
0012
0013 ``QCollectionGenerator_FOUND``
0014     True if (the requested version of) Sphinx is available
0015 ``QCollectionGenerator_VERSION``
0016     The version of the Qt help collection generator. Note that this not the
0017     same as the version of Qt it is provided by.
0018 ``QCollectionGenerator_QT_VERSION``
0019     The version of Qt that the Qt help collection generator is from.
0020 ``QCollectionGenerator_EXECUTABLE``
0021     The path to the Qt help collection generator executable.
0022
0023 If ``QCollectionGenerator_FOUND`` is TRUE, it will also define the following
0024 imported target:
0025
0026 ``QCollectionGenerator::Generator``
0027     The Qt help collection generator.
0028
0029 In general we recommend using the imported target, as it is easier to use.
0030
0031 Since 5.17.0.
0032 #]=======================================================================]
0033
0034 find_program(QCollectionGenerator_EXECUTABLE
0035     NAMES
0036         qcollectiongenerator
0037         qcollectiongenerator-qt4
0038         qcollectiongenerator-qt5
0039     DOC "Qt help collection generator"
0040 )
0041
0042 if (QCollectionGenerator_EXECUTABLE)
0043     if(NOT TARGET QCollectionGenerator::Generator)
0044         add_executable(QCollectionGenerator::Generator IMPORTED)
0045         set_target_properties(QCollectionGenerator::Generator PROPERTIES
0046             IMPORTED_LOCATION "${QCollectionGenerator_EXECUTABLE}"
0047         )
0048     endif()
0049
0050     execute_process(
0051         COMMAND "${QCollectionGenerator_EXECUTABLE}" -v
0052         OUTPUT_VARIABLE _QCollectionGenerator_version_raw
0053         ERROR_VARIABLE _QCollectionGenerator_version_raw
0054     )
0055     if (_QCollectionGenerator_version_raw MATCHES "^Qt Collection Generator version ([0-9]+(\\.[0-9]+)*) \\(Qt ([0-9]+(\\.[0-9]+)*)\\)")
0056         set(QCollectionGenerator_VERSION "${CMAKE_MATCH_1}")
0057         set(QCollectionGenerator_QT_VERSION "${CMAKE_MATCH_3}")
0058     endif()
0059     unset(_QCollectionGenerator_version_raw)
0060 endif()
0061
0062 include(FindPackageHandleStandardArgs)
0063 find_package_handle_standard_args(QCollectionGenerator
0064     FOUND_VAR
0065         QCollectionGenerator_FOUND
0066     REQUIRED_VARS
0067         QCollectionGenerator_EXECUTABLE
0068     VERSION_VAR
0069         QCollectionGenerator_VERSION
0070 )
0071
0072 mark_as_advanced(QCollectionGenerator_EXECUTABLE)