bluez-qt/src/CMakeLists.txt

0001 set(bluezqt_SRCS
0002     a2dp-codecs.c
0003     manager.cpp
0004     manager_p.cpp
0005     adapter.cpp
0006     adapter_p.cpp
0007     battery.cpp
0008     device.cpp
0009     device_p.cpp
0010     gattapplication.cpp
0011     gattapplication_p.cpp
0012     gattcharacteristic.cpp
0013     gattcharacteristic_p.cpp
0014     gattcharacteristicadaptor.cpp
0015     gattmanager.cpp
0016     gattmanager_p.cpp
0017     gattservice.cpp
0018     gattservice_p.cpp
0019     gattserviceadaptor.cpp
0020     gattserviceremote.cpp
0021     gattserviceremote_p.cpp
0022     gattcharacteristicremote.cpp
0023     gattcharacteristicremote_p.cpp
0024     gattdescriptorremote.cpp
0025     gattdescriptorremote_p.cpp
0026     input.cpp
0027     leadvertisement.cpp
0028     leadvertisement_p.cpp
0029     leadvertisementadaptor.cpp
0030     leadvertisingmanager.cpp
0031     media.cpp
0032     mediaendpoint.cpp
0033     mediaendpoint_p.cpp
0034     mediaendpointadaptor.cpp
0035     mediaplayer.cpp
0036     mediaplayer_p.cpp
0037     mediaplayertrack.cpp
0038     mediatransport.cpp
0039     mediatransport_p.cpp
0040     objectmanageradaptor.cpp
0041     devicesmodel.cpp
0042     job.cpp
0043     initmanagerjob.cpp
0044     initobexmanagerjob.cpp
0045     utils.cpp
0046     agent.cpp
0047     agentadaptor.cpp
0048     profile.cpp
0049     profileadaptor.cpp
0050     pendingcall.cpp
0051     request.cpp
0052     rfkill.cpp
0053     obexmanager.cpp
0054     obexmanager_p.cpp
0055     obexagent.cpp
0056     obexagentadaptor.cpp
0057     obextransfer.cpp
0058     obexsession.cpp
0059     obexobjectpush.cpp
0060     obexfiletransfer.cpp
0061     obexfiletransferentry.cpp
0062 )
0063
0064 ecm_qt_declare_logging_category(bluezqt_SRCS
0065     HEADER debug.h
0066     IDENTIFIER BLUEZQT
0067     CATEGORY_NAME kf.bluezqt
0068     OLD_CATEGORY_NAMES org.kde.bluez
0069     DESCRIPTION "BluezQt"
0070     EXPORT BLUEZQT
0071 )
0072
0073 set(dbusobjectmanager_xml ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.freedesktop.DBus.ObjectManager.xml)
0074 set_source_files_properties(${dbusobjectmanager_xml} PROPERTIES INCLUDE "bluezqt_dbustypes.h")
0075 qt_add_dbus_interface(bluezqt_SRCS ${dbusobjectmanager_xml} dbusobjectmanager)
0076
0077 set(obexfiletransfer1_xml ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.FileTransfer1.xml)
0078 set_source_files_properties(${obexfiletransfer1_xml} PROPERTIES INCLUDE "bluezqt_dbustypes.h")
0079 qt_add_dbus_interface(bluezqt_SRCS ${obexfiletransfer1_xml} obexfiletransfer1)
0080
0081 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.GattDescriptor1.xml bluezgattdescriptor1)
0082 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.GattService1.xml bluezgattservice1)
0083 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.freedesktop.DBus.Properties.xml dbusproperties)
0084 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.Adapter1.xml bluezadapter1)
0085 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.AgentManager1.xml bluezagentmanager1)
0086 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.Battery1.xml bluezbattery1)
0087 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.GattCharacteristic1.xml bluezgattcharacteristic1)
0088 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.GattManager1.xml bluezgattmanager1)
0089 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.ProfileManager1.xml bluezprofilemanager1)
0090 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.Device1.xml bluezdevice1)
0091 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.LEAdvertisement1.xml bluezleadvertisement1)
0092 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.LEAdvertisingManager1.xml bluezleadvertisingmanager1)
0093 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.Media1.xml bluezmedia1)
0094 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.MediaEndpoint1.xml bluezmediaendpoint1)
0095 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.MediaPlayer1.xml bluezmediaplayer1)
0096 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.MediaTransport1.xml bluezmediatransport1)
0097 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.AgentManager1.xml obexagentmanager1)
0098 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.Client1.xml obexclient1)
0099 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.Transfer1.xml obextransfer1)
0100 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.Session1.xml obexsession1)
0101 qt_add_dbus_interface(bluezqt_SRCS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces/org.bluez.obex.ObjectPush1.xml obexobjectpush1)
0102
0103 add_library(KF5BluezQt ${bluezqt_SRCS})
0104 add_library(KF5::BluezQt ALIAS KF5BluezQt)
0105 ecm_generate_export_header(KF5BluezQt
0106     BASE_NAME BluezQt
0107     GROUP_BASE_NAME KF
0108     VERSION ${KF_VERSION}
0109     DEPRECATED_BASE_VERSION 0
0110     DEPRECATION_VERSIONS 5.57
0111     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0112 )
0113
0114 target_include_directories(KF5BluezQt INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt>")
0115
0116 target_link_libraries(KF5BluezQt
0117     PUBLIC
0118         Qt${QT_MAJOR_VERSION}::Core
0119     PRIVATE
0120         Qt${QT_MAJOR_VERSION}::DBus
0121         Qt${QT_MAJOR_VERSION}::Network
0122 )
0123
0124 set_target_properties(KF5BluezQt
0125     PROPERTIES VERSION ${BLUEZQT_VERSION}
0126     SOVERSION ${BLUEZQT_SOVERSION}
0127     EXPORT_NAME "BluezQt"
0128 )
0129
0130 ecm_generate_headers(BluezQt_CamelCase_HEADERS
0131     HEADER_NAMES
0132         Types
0133         Manager
0134         Adapter
0135         Device
0136         GattApplication
0137         GattCharacteristic
0138         GattManager
0139         GattService
0140         GattServiceRemote
0141         GattCharacteristicRemote
0142         GattDescriptorRemote
0143         Input
0144         LEAdvertisement
0145         LEAdvertisingManager
0146         Media
0147         MediaEndpoint
0148         MediaPlayer
0149         MediaPlayerTrack
0150         MediaTransport
0151         MediaTypes
0152         TPendingCall
0153         DevicesModel
0154         Job
0155         InitManagerJob
0156         InitObexManagerJob
0157         Services
0158         Agent
0159         Profile
0160         PendingCall
0161         Request
0162         Rfkill
0163         ObexManager
0164         ObexAgent
0165         ObexTransfer
0166         ObexSession
0167         ObexObjectPush
0168         ObexFileTransfer
0169         ObexFileTransferEntry
0170
0171     REQUIRED_HEADERS BluezQt_HEADERS
0172     PREFIX BluezQt
0173 )
0174
0175 # Install files
0176 install(TARGETS KF5BluezQt
0177         EXPORT KF5BluezQtTargets
0178         ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0179
0180 install(FILES
0181     ${BluezQt_CamelCase_HEADERS}
0182     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt/BluezQt
0183     COMPONENT Devel)
0184
0185 install(FILES
0186     ${CMAKE_CURRENT_BINARY_DIR}/bluezqt_export.h
0187     ${BluezQt_HEADERS}
0188     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt/bluezqt
0189     COMPONENT Devel)
0190
0191 ecm_qt_install_logging_categories(
0192     EXPORT BLUEZQT
0193     FILE bluezqt.categories
0194     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0195 )
0196
0197
0198 if(BUILD_QCH)
0199     ecm_add_qch(
0200         KF5BluezQt_QCH
0201         NAME BluezQt
0202         BASE_NAME KF5BluezQt
0203         VERSION ${KF_VERSION}
0204         ORG_DOMAIN org.kde
0205         SOURCES # using only public headers, to cover only public API
0206             ${BluezQt_HEADERS}
0207         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0208         LINK_QCHS
0209             Qt${QT_MAJOR_VERSION}Core_QCH
0210         INCLUDE_DIRS
0211             ${CMAKE_CURRENT_BINARY_DIR}
0212         BLANK_MACROS
0213             BLUEZQT_EXPORT
0214             BLUEZQT_DEPRECATED
0215             BLUEZQT_DEPRECATED_EXPORT
0216             "BLUEZQT_DEPRECATED_VERSION(x, y, t)"
0217         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0218         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0219         COMPONENT Devel
0220     )
0221 endif()
0222
0223 include(ECMGeneratePriFile)
0224
0225 ecm_generate_pri_file(
0226     BASE_NAME BluezQt
0227     LIB_NAME KF5BluezQt
0228     DEPS "core"
0229     FILENAME_VAR PRI_FILENAME
0230     INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt
0231 )
0232 install(FILES ${PRI_FILENAME}
0233         DESTINATION ${ECM_MKSPECS_INSTALL_DIR})