frameworks/bluez-qt/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(BluezQt VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0 NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEGitCommitHooks)
0016 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0017
0018 include(FeatureSummary)
0019 include(ECMGenerateExportHeader)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022 include(ECMAddQch)
0023 include(CMakePackageConfigHelpers)
0024 include(ECMQtDeclareLoggingCategory)
0025 include(ECMGeneratePkgConfigFile)
0026 include(ECMQmlModule)
0027 include(ECMDeprecationSettings)
0028
0029 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0030
0031 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0032 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0033
0034 set(bluezqt_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/bluezqt_version.h")
0035 ecm_setup_version(PROJECT
0036     VARIABLE_PREFIX BLUEZQT
0037     VERSION_HEADER "${bluezqt_version_header}"
0038     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6BluezQtConfigVersion.cmake"
0039     SOVERSION 6
0040 )
0041
0042 # Dependencies
0043 set(REQUIRED_QT_VERSION 6.5.0)
0044
0045 # Required Qt components to build this framework
0046 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core DBus Network)
0047
0048 # Optional Qt components to build this framework
0049 find_package(Qt6Test ${REQUIRED_QT_VERSION} CONFIG)
0050 set_package_properties(Qt6Test PROPERTIES DESCRIPTION "Autotests for BluezQt" TYPE OPTIONAL)
0051 find_package(Qt6Qml ${REQUIRED_QT_VERSION} CONFIG)
0052 set_package_properties(Qt6Qml PROPERTIES DESCRIPTION "QML support for BluezQt" TYPE OPTIONAL)
0053 find_package(Qt6QuickTest ${REQUIRED_QT_VERSION} CONFIG)
0054 set_package_properties(Qt6QuickTest PROPERTIES DESCRIPTION "QML autotests for BluezQt" TYPE OPTIONAL)
0055
0056 ecm_set_disabled_deprecation_versions(
0057     QT 6.5
0058 )
0059
0060 # Subdirectories
0061 add_subdirectory(src)
0062 add_subdirectory(tools/bluezapi2qt)
0063
0064 if (BUILD_TESTING)
0065     add_subdirectory(tests)
0066     if(Qt6Test_FOUND)
0067         add_subdirectory(autotests)
0068     endif()
0069 endif()
0070
0071 if(Qt6Qml_FOUND)
0072     add_subdirectory(src/imports)
0073 endif()
0074
0075 # Create a Config.cmake and a ConfigVersion.cmake file and install them
0076 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6BluezQt")
0077
0078 if (BUILD_QCH)
0079     ecm_install_qch_export(
0080         TARGETS KF6BluezQt_QCH
0081         FILE KF6BluezQtQchTargets.cmake
0082         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0083         COMPONENT Devel
0084     )
0085     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6BluezQtQchTargets.cmake\")")
0086 endif()
0087
0088 configure_package_config_file(
0089     "${CMAKE_CURRENT_SOURCE_DIR}/KF6BluezQtConfig.cmake.in"
0090     "${CMAKE_CURRENT_BINARY_DIR}/KF6BluezQtConfig.cmake"
0091     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092 )
0093
0094 install(FILES
0095     "${CMAKE_CURRENT_BINARY_DIR}/KF6BluezQtConfig.cmake"
0096     "${CMAKE_CURRENT_BINARY_DIR}/KF6BluezQtConfigVersion.cmake"
0097     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0098     COMPONENT Devel)
0099
0100 install(EXPORT KF6BluezQtTargets
0101     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0102     FILE KF6BluezQtTargets.cmake
0103     NAMESPACE KF6::)
0104
0105 install(FILES
0106     ${bluezqt_version_header}
0107     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt
0108     COMPONENT Devel)
0109
0110 ecm_generate_pkgconfig_file(BASE_NAME KF6BluezQt
0111   INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/BluezQt/
0112   DEPS "Qt6Core Qt6Network Qt6DBus"
0113 INSTALL)
0114
0115 include(ECMFeatureSummary)
0116 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0117
0118 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)