src/file/CMakeLists.txt

0001 include_directories(${Inotify_INCLUDE_DIRS})
0002 add_definitions(-DTRANSLATION_DOMAIN=\"baloo_file6\")
0003
0004 set(file_static_lib_SRCS
0005     # File Indexer
0006     mainhub.cpp
0007     fileindexerconfig.cpp
0008     basicindexingjob.cpp
0009     powerstatemonitor.cpp
0010
0011     fileindexscheduler.cpp
0012
0013     firstrunindexer.cpp
0014     newfileindexer.cpp
0015     xattrindexer.cpp
0016     modifiedfileindexer.cpp
0017     unindexedfileindexer.cpp
0018
0019     filecontentindexer.cpp
0020     filecontentindexerprovider.cpp
0021     extractorprocess.cpp
0022     extractor/commandpipe.cpp
0023     timeestimator.cpp
0024
0025     indexcleaner.cpp
0026
0027     # Common
0028     priority.cpp
0029     regexpcache.cpp
0030     fileexcludefilters.cpp
0031     storagedevices.cpp
0032     filtereddiriterator.cpp
0033     unindexedfileiterator.cpp
0034     migrator.cpp
0035
0036      # File Watcher
0037     filewatch.cpp
0038     pendingfilequeue.cpp
0039     metadatamover.cpp
0040     org.kde.BalooWatcherApplication.xml
0041     pendingfile.cpp
0042     kinotify.cpp
0043
0044     propertydata.cpp
0045 )
0046
0047 ecm_qt_declare_logging_category(file_static_lib_SRCS
0048     HEADER baloodebug.h
0049     IDENTIFIER BALOO
0050     CATEGORY_NAME kf.baloo
0051 )
0052
0053 # KF6 TODO - remove BalooWatcherApplication
0054 qt_add_dbus_interface(file_static_lib_SRCS org.kde.BalooWatcherApplication.xml baloowatcherapplication_interface)
0055 kconfig_add_kcfg_files(file_static_lib_SRCS ../lib/baloosettings.kcfgc GENERATE_MOC)
0056
0057 add_library(baloofilecommon STATIC ${file_static_lib_SRCS})
0058 target_link_libraries(baloofilecommon
0059     Qt6::DBus
0060     KF6::I18n
0061     KF6::Solid
0062     KF6::FileMetaData
0063     KF6::ConfigCore
0064     KF6::BalooEngine
0065     ${Inotify_LIBRARIES}
0066 )
0067
0068 set(file_SRCS
0069     main.cpp
0070 )
0071
0072 if (BUILD_INDEXER_SERVICE)
0073     add_executable(baloo_file ${file_SRCS})
0074     ecm_mark_nongui_executable(baloo_file)
0075     target_compile_definitions(baloo_file PRIVATE -DPROJECT_VERSION="${PROJECT_VERSION}")
0076
0077     target_link_libraries(baloo_file
0078         baloofilecommon
0079         KF6::Crash
0080     )
0081
0082     install(TARGETS baloo_file DESTINATION ${KDE_INSTALL_FULL_LIBEXECDIR_KF})
0083
0084     ecm_install_configured_files(INPUT baloo_file.desktop.in DESTINATION ${KDE_INSTALL_AUTOSTARTDIR})
0085
0086     ecm_install_configured_files(
0087        INPUT kde-baloo.service.in
0088        DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR}
0089     )
0090
0091     add_subdirectory(extractor)
0092
0093     install(FILES
0094         org.kde.BalooWatcherApplication.xml
0095         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0096     )
0097 endif()
0098