src/dbus/CMakeLists.txt

0001 # Cannot use INTERFACE libraries, as cmake (at least 3.25) seems
0002 # to not add dependencies for generated sources that are added as INTERFACE sources.
0003 # So using STATIC libraries instead.
0004
0005 #
0006 # MainHub
0007 #
0008 add_library(BalooDBusMainInterface STATIC)
0009 set_target_properties(BalooDBusMainInterface PROPERTIES POSITION_INDEPENDENT_CODE ON)
0010
0011 set(mainhub_xml org.kde.baloo.main.xml)
0012
0013 qt_generate_dbus_interface(
0014     ${CMAKE_SOURCE_DIR}/src/file/mainhub.h
0015     ${mainhub_xml}
0016     OPTIONS -a
0017 )
0018
0019 qt_add_dbus_interface(maininterface_SRCS
0020     ${CMAKE_CURRENT_BINARY_DIR}/${mainhub_xml}
0021     maininterface
0022 )
0023
0024 target_sources(BalooDBusMainInterface PRIVATE ${maininterface_SRCS})
0025 target_link_libraries(BalooDBusMainInterface PUBLIC Qt6::DBus)
0026
0027 #
0028 # FileIndexScheduler
0029 #
0030 add_library(BalooDBusSchedulerInterface STATIC)
0031 set_target_properties(BalooDBusSchedulerInterface PROPERTIES POSITION_INDEPENDENT_CODE ON)
0032
0033 set(scheduler_xml org.kde.baloo.scheduler.xml)
0034
0035 qt_generate_dbus_interface(
0036     ${CMAKE_SOURCE_DIR}/src/file/fileindexscheduler.h
0037     ${scheduler_xml}
0038     OPTIONS -a
0039 )
0040
0041 qt_add_dbus_interface(schedulerinterface_SRCS
0042     ${CMAKE_CURRENT_BINARY_DIR}/${scheduler_xml}
0043     schedulerinterface
0044 )
0045
0046 target_sources(BalooDBusSchedulerInterface PRIVATE ${schedulerinterface_SRCS})
0047 target_link_libraries(BalooDBusSchedulerInterface PUBLIC Qt6::DBus)
0048
0049 #
0050 # FileContentIndexer
0051 #
0052 add_library(BalooDBusFileIndexerInterface STATIC)
0053 set_target_properties(BalooDBusFileIndexerInterface PROPERTIES POSITION_INDEPENDENT_CODE ON)
0054
0055 set(contentindexer_xml org.kde.baloo.fileindexer.xml)
0056
0057 qt_generate_dbus_interface(
0058     ${CMAKE_SOURCE_DIR}/src/file/filecontentindexer.h
0059     ${contentindexer_xml}
0060     OPTIONS -a
0061 )
0062
0063 qt_add_dbus_interface(fileindexerinterface_SRCS
0064     ${CMAKE_CURRENT_BINARY_DIR}/${contentindexer_xml}
0065     fileindexerinterface
0066 )
0067
0068 target_sources(BalooDBusFileIndexerInterface PRIVATE ${fileindexerinterface_SRCS})
0069 target_link_libraries(BalooDBusFileIndexerInterface PUBLIC Qt6::DBus)
0070
0071
0072 if (BUILD_INDEXER_SERVICE)
0073     install(FILES
0074             ${CMAKE_CURRENT_BINARY_DIR}/${mainhub_xml}
0075             ${CMAKE_CURRENT_BINARY_DIR}/${scheduler_xml}
0076             ${CMAKE_CURRENT_BINARY_DIR}/${contentindexer_xml}
0077         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0078     )
0079
0080     add_subdirectory(fake)
0081 endif()
0082