education/step/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "08")
0006 set(RELEASE_SERVICE_VERSION_MICRO "1")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(step VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(KDE_COMPILERSETTINGS_LEVEL "5.84")
0012 set(QT_MIN_VERSION "5.15.2")
0013 set(KF_MIN_VERSION "5.90.0")
0014
0015 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0017 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules" ${CMAKE_MODULE_PATH})
0018
0019 include(KDEInstallDirs)
0020 include(ECMAddTests)
0021 include(KDECompilerSettings NO_POLICY_SCOPE)
0022 include(KDECMakeSettings)
0023 include(ECMInstallIcons)
0024 include(ECMOptionalAddSubdirectory)
0025 include(ECMSetupVersion)
0026 include(FeatureSummary)
0027 include(ECMPoQmTools)
0028
0029 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS
0030     Xml
0031     Svg
0032 )
0033 if (QT_MAJOR_VERSION STREQUAL "6")
0034     find_package(Qt6 REQUIRED NO_MODULE COMPONENTS OpenGLWidgets)
0035 endif()
0036
0037 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     Crash
0039     Config
0040     I18n
0041     IconThemes
0042     KIO
0043     NewStuff
0044     Plotting
0045     TextWidgets
0046     XmlGui
0047 )
0048 find_package(KF${QT_MAJOR_VERSION}DocTools ${KF_MIN_VERSION})
0049 find_package(Eigen3 3.2.2 REQUIRED)
0050 find_package(GSL)
0051 find_package(Qalculate)
0052
0053 set_package_properties(EIGEN3 PROPERTIES
0054                        DESCRIPTION "Eigen3"
0055                        URL "https://eigen.tuxfamily.org"
0056                        TYPE OPTIONAL
0057                        PURPOSE "Required to build step")
0058
0059 set_package_properties(QALCULATE PROPERTIES
0060 #                      REQUIRED_VERSION "0.9.5"
0061                        DESCRIPTION "Qalculate"
0062                        URL "https://qalculate.github.io/"
0063                        TYPE OPTIONAL
0064                        PURPOSE "Unit conversion support in Step")
0065
0066 set_package_properties(GSL PROPERTIES
0067 #                      REQUIRED_VERSION "1.8"
0068                        DESCRIPTION "GSL"
0069                        URL "https://www.gnu.org/software/gsl/"
0070                        TYPE OPTIONAL
0071                        PURPOSE "Provides a GSL-powered solver for Step")
0072
0073 set(STEPCORE_WITH_GSL ${GSL_FOUND} CACHE BOOL "Enable GSL-powered features for StepCore")
0074 set(STEPCORE_WITH_QT ON) # CACHE BOOL "Enable QT-powered features for StepCore")
0075 set(STEP_WITH_QALCULATE ${QALCULATE_FOUND} CACHE BOOL "Enable unit conversion support using libqalculate")
0076 if (QT_MAJOR_VERSION STREQUAL "6")
0077     MESSAGE(STATUS "QALCULATE was not ported to QT6 yet")
0078     set(STEP_WITH_QALCULATE false)
0079 endif()
0080
0081 # Compiler specific options
0082 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
0083     # Clang specific options
0084     include(${CMAKE_CURRENT_SOURCE_DIR}/Clang.cmake)
0085 elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
0086     # GCC specific options
0087     include(${CMAKE_CURRENT_SOURCE_DIR}/GCC.cmake)
0088 else()
0089     # Some other compiler
0090 endif()
0091
0092 if(KF${QT_MAJOR_VERSION}DocTools_FOUND)
0093     ecm_optional_add_subdirectory(doc)
0094 endif()
0095 add_subdirectory(stepcore)
0096 add_subdirectory(step)
0097 add_subdirectory(autotests)
0098
0099 ecm_install_po_files_as_qm(poqm)
0100 ki18n_install(po)
0101 if (KF${QT_MAJOR_VERSION}DocTools_FOUND)
0102     kdoctools_install(po)
0103 endif()
0104 install(FILES org.kde.step.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0105
0106 find_package(SharedMimeInfo REQUIRED)
0107 install(FILES org.kde.step.xml DESTINATION ${KDE_INSTALL_MIMEDIR})
0108 update_xdg_mimetypes(${KDE_INSTALL_MIMEDIR})
0109
0110 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)