education/minuet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
0002
0003 set(CMAKE_AUTOMOC ON)
0004 if(${CMAKE_VERSION} VERSION_GREATER "3.10.0")
0005     cmake_policy(SET CMP0071 OLD)
0006 endif()
0007
0008 # KDE Application Version, managed by release script
0009 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0010 set (RELEASE_SERVICE_VERSION_MINOR "03")
0011 set (RELEASE_SERVICE_VERSION_MICRO "70")
0012 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0013 set (MINUET_VERSION "0.4.0.${RELEASE_SERVICE_COMPACT_VERSION}")
0014
0015 project(minuet VERSION ${MINUET_VERSION})
0016
0017 set(KF5_MIN_VERSION "5.90.0")
0018 set(QT_MIN_VERSION "5.15.2")
0019
0020 find_package(ECM ${KF5_MIN_VERSION} CONFIG REQUIRED)
0021 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH}  ${minuet_SOURCE_DIR}/cmake)
0022
0023 include(GenerateExportHeader)
0024 include(ECMSetupVersion)
0025 include(ECMInstallIcons)
0026 include(ECMAddAppIcon)
0027 include(KDEClangFormat)
0028 include(KDEInstallDirs)
0029 include(KDECMakeSettings)
0030 include(FeatureSummary)
0031
0032 ecm_setup_version(${MINUET_VERSION} VARIABLE_PREFIX MINUET
0033     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/app/minuet_version.h"
0034 )
0035
0036 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS
0037     Core
0038     Gui
0039     Qml
0040     Quick
0041     QuickControls2
0042     Svg
0043 )
0044
0045 IF(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Android")
0046     find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0047         CoreAddons
0048         I18n
0049         Crash
0050         DocTools
0051     )
0052     find_package(FluidSynth 1.1.6 REQUIRED)
0053 ENDIF(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Android")
0054
0055 include_directories(${minuet_SOURCE_DIR}/src/ ${minuet_BINARY_DIR}/src/)
0056
0057 add_subdirectory(src)
0058 add_subdirectory(data)
0059 IF(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Android")
0060     add_subdirectory(doc)
0061     ki18n_install(po)
0062     if (KF5DocTools_FOUND)
0063         kdoctools_install(po)
0064     endif()
0065     install(FILES org.kde.minuet.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0066 ENDIF(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Android")
0067
0068 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)