labplot/cmake/FindLibOrigin.cmake

0001 #=============================================================================
0002 # SPDX-FileCopyrightText: 2023 Stefan Gerlach <stefan.gerlach@uni.kn>
0003 #
0004 # SPDX-License-Identifier: BSD-3-Clause
0005 #=============================================================================
0006
0007 find_package(PkgConfig QUIET)
0008 if (PKG_CONFIG_FOUND)
0009         pkg_check_modules(PC_LIBORIGIN liborigin>=3.0.3 QUIET)
0010 endif ()
0011
0012 find_library(LIBORIGIN_LIBRARIES
0013     NAMES origin
0014     HINTS ${PC_LIBORIGIN_LIBRARY_DIRS}
0015 )
0016
0017 find_path(LIBORIGIN_INCLUDE_DIR
0018     NAMES OriginFile.h
0019     HINTS ${PC_LIBORIGIN_INCLUDE_DIRS}
0020 )
0021
0022 set(LIBORIGIN_VERSION ${PC_LIBORIGIN_VERSION})
0023
0024 include(FindPackageHandleStandardArgs)
0025 find_package_handle_standard_args(LibOrigin
0026     REQUIRED_VARS
0027         LIBORIGIN_LIBRARIES
0028         LIBORIGIN_INCLUDE_DIR
0029     VERSION_VAR
0030         LIBORIGIN_VERSION
0031 )
0032
0033 if(LIBORIGIN_FOUND)
0034     add_library(liborigin UNKNOWN IMPORTED)
0035     set_target_properties(liborigin PROPERTIES
0036             IMPORTED_LOCATION "${LIBORIGIN_LIBRARIES}"
0037             INTERFACE_COMPILE_OPTIONS "${PC_LIBORIGIN_CFLAGS}"
0038             INTERFACE_INCLUDE_DIRECTORIES "${LIBORIGIN_INCLUDE_DIR}"
0039     )
0040 endif()
0041
0042 mark_as_advanced(LIBORIGIN_LIBRARIES LIBORIGIN_INCLUDE_DIR LIBORIGIN_VERSION)
0043
0044 include(FeatureSummary)
0045 set_package_properties(LibOrigin PROPERTIES
0046     DESCRIPTION "A library for reading OriginLab project files"
0047     URL "http://sourceforge.net/projects/liborigin"
0048 )
0049