labplot/cmake/FindFFTW3.cmake

0001 #=============================================================================
0002 # SPDX-FileCopyrightText: 2019 Harald Sitter <sitter@kde.org>
0003 #
0004 # SPDX-License-Identifier: BSD-3-Clause
0005 #=============================================================================
0006
0007 find_package(PkgConfig QUIET)
0008 pkg_check_modules(PC_FFTW3 fftw3 QUIET)
0009
0010 find_library(FFTW3_LIBRARIES
0011     NAMES fftw3
0012     HINTS ${PC_FFTW3_LIBRARY_DIRS}
0013 )
0014
0015 find_path(FFTW3_INCLUDE_DIR
0016     NAMES fftw3.h
0017     HINTS ${PC_FFTW3_INCLUDE_DIRS}
0018     PATH_SUFFIXES fftw3
0019 )
0020
0021 set(FFTW3_VERSION ${PC_FFTW3_VERSION})
0022
0023 include(FindPackageHandleStandardArgs)
0024 find_package_handle_standard_args(FFTW3
0025     REQUIRED_VARS
0026         FFTW3_LIBRARIES
0027         FFTW3_INCLUDE_DIR
0028     VERSION_VAR
0029         FFTW3_VERSION
0030 )
0031
0032 if(FFTW3_FOUND AND NOT TARGET FFTW3::FFTW3)
0033     add_library(FFTW3::FFTW3 UNKNOWN IMPORTED)
0034     set_target_properties(FFTW3::FFTW3 PROPERTIES
0035         IMPORTED_LOCATION "${FFTW3_LIBRARIES}"
0036         INTERFACE_COMPILE_OPTIONS "${PC_FFTW3_CFLAGS}"
0037         INTERFACE_INCLUDE_DIRECTORIES "${FFTW3_INCLUDE_DIR}"
0038     )
0039 else()
0040     set(FFTW3_LIBRARIES "")
0041 endif()
0042
0043 mark_as_advanced(FFTW3_LIBRARIES FFTW3_INCLUDE_DIR FFTW3_VERSION)
0044
0045 include(FeatureSummary)
0046 set_package_properties(FFTW3 PROPERTIES
0047     DESCRIPTION "Computing the Discrete Fourier Transform in one or more dimensions"
0048     URL "http://fftw.org/"
0049 )
0050