analitza/analitzaplot/CMakeLists.txt

0001 if(WIN32)
0002     find_package(GLEW REQUIRED)
0003     include_directories(${GLEW_INCLUDE_DIRS})
0004 endif(WIN32)
0005
0006 find_path(IEEEFP_DIR ieeefp.h)
0007 if(IEEEFP_DIR)
0008     include_directories(${IEEEFP_DIR})
0009     add_definitions(-DHAVE_IEEEFP_H)
0010 endif(IEEEFP_DIR)
0011
0012 # MSVC and MinGW don't provide M_PI and friends in math.h,
0013 # unless the right #define is set:
0014 if(MSVC)
0015     add_definitions(-D_USE_MATH_DEFINES)
0016 elseif(MINGW)
0017     add_definitions(-D_BSD_SOURCE)
0018 endif()
0019
0020 set ( analitzaplot_SRCS
0021     private/utils/mathutils.cpp
0022     private/utils/quadtree.cpp
0023     private/utils/marchingsquares.cpp
0024     private/utils/marchingcubes.cpp
0025
0026     private/abstractplotitem.cpp
0027     private/abstractfunctiongraph.cpp
0028     private/abstractplanecurve.cpp
0029     private/abstractspacecurve.cpp
0030     private/abstractsurface.cpp
0031     private/functiongraphfactory.cpp
0032     private/export3d.cpp
0033
0034     private/backends/cartesiansurface.cpp
0035     private/backends/implicitcurve.cpp
0036     private/backends/cartesiancurve.cpp
0037     private/backends/cylindricalsurface.cpp
0038     private/backends/parametriccurve2d.cpp
0039     private/backends/parametriccurve3d.cpp
0040     private/backends/parametricsurface.cpp
0041     private/backends/polarcurve.cpp
0042     private/backends/implicitpolarcurve.cpp
0043     private/backends/sphericalsurface.cpp
0044     private/backends/implicitsurface.cpp
0045
0046     plotsfactory.cpp
0047     plotitem.cpp
0048     functiongraph.cpp
0049     planecurve.cpp
0050     spacecurve.cpp
0051     surface.cpp
0052     plotsmodel.cpp
0053     plotsdictionarymodel.cpp
0054     plotter2d.cpp
0055     plotter3d_es.cpp
0056 )
0057
0058 add_library(AnalitzaPlot ${analitzaplot_SRCS})
0059 target_link_libraries(AnalitzaPlot
0060     PUBLIC
0061         Analitza
0062         Qt6::Core
0063         Qt6::Gui
0064
0065     PRIVATE
0066         Qt6::PrintSupport # this pulls widgets
0067         Qt6::OpenGL
0068 )
0069
0070 if(CMAKE_SYSTEM_NAME STREQUAL Android)
0071     target_link_libraries(AnalitzaPlot PRIVATE GLESv2)
0072 elseif(WIN32)
0073     target_link_libraries(AnalitzaPlot PRIVATE ${GLEW_LIBRARIES})
0074 endif()
0075
0076 set_target_properties(AnalitzaPlot PROPERTIES VERSION ${ANALITZA_VERSION} SOVERSION ${ANALITZA_SOVERSION} )
0077
0078 generate_export_header(AnalitzaPlot EXPORT_FILE_NAME analitzaplotexport.h)
0079
0080 install(TARGETS AnalitzaPlot EXPORT AnalitzaTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0081
0082 install(FILES
0083     ${CMAKE_CURRENT_BINARY_DIR}/analitzaplotexport.h
0084     plotitem.h
0085     functiongraph.h
0086     planecurve.h
0087     spacecurve.h
0088     surface.h
0089     plotsmodel.h
0090     plotsdictionarymodel.h
0091     plotter2d.h
0092     plottingenums.h
0093     plotsfactory.h
0094     plotter3d_es.h
0095
0096     DESTINATION ${ANALITZA_INCLUDE_INSTALL_DIR}/analitzaplot/ COMPONENT Devel
0097 )
0098
0099 add_subdirectory(data)
0100 add_subdirectory(tests)
0101 add_subdirectory(examples)
0102