education/analitza/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002 set(ANALITZA_VERSION "8.0.0")
0003 project(Analitza VERSION ${ANALITZA_VERSION})
0004
0005 set(QT_MIN_VERSION "5.15.2")
0006 set(KF5_MIN_VERSION "5.90.0")
0007 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0008
0009 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0010 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0011
0012 #Checking whether we can compile calgebra
0013
0014
0015 include(CMakePackageConfigHelpers)
0016 include(FeatureSummary)
0017 include(ECMAddAppIcon)
0018 include(ECMSetupVersion)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020 include(ECMAddTests)
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(GenerateExportHeader)
0024 include(CheckIncludeFiles)
0025 include(CheckLibraryExists) #FindCurses seems to need that on the CI
0026 include(ECMPoQmTools)
0027 find_package(Qt${QT_MAJOR_VERSION} ${QT_REQUIRED_VERSION} REQUIRED NO_MODULE COMPONENTS Widgets Xml Svg Test Qml Quick PrintSupport)
0028 if (QT_MAJOR_VERSION STREQUAL "6")
0029     find_package(Qt6 REQUIRED NO_MODULE COMPONENTS Core5Compat OpenGLWidgets)
0030 endif()
0031 set(ANALITZA_INCLUDE_INSTALL_DIR "${KDE_INSTALL_INCLUDEDIR}/Analitza5")
0032
0033 ecm_setup_version(8.0.0 VARIABLE_PREFIX ANALITZA
0034                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/analitza_version.h"
0035                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/Analitza5ConfigVersion.cmake")
0036
0037 find_package(Eigen3 CONFIG) # find and setup Eigen3 if available
0038 set(HAVE_EIGEN3 ${EIGEN3_FOUND})
0039
0040 include_directories(${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR})
0041
0042 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0043 remove_definitions(-DQT_NO_CAST_FROM_BYTEARRAY)
0044
0045
0046 add_subdirectory(analitza)
0047 add_subdirectory(analitzaplot)
0048 add_subdirectory(analitzagui)
0049 add_subdirectory(analitzawidgets)
0050 add_subdirectory(declarative)
0051
0052 ecm_install_po_files_as_qm(poqm)
0053
0054 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/Analitza5")
0055 configure_package_config_file(
0056   "${CMAKE_CURRENT_SOURCE_DIR}/Analitza5Config.cmake.in"
0057   "${CMAKE_CURRENT_BINARY_DIR}/Analitza5Config.cmake"
0058   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0059   PATH_VARS  KDE_INSTALL_INCLUDEDIR CMAKE_INSTALL_PREFIX
0060 )
0061
0062 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/config-analitza.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-analitza.h)
0063
0064 install(FILES
0065   "${CMAKE_CURRENT_BINARY_DIR}/Analitza5Config.cmake"
0066   "${CMAKE_CURRENT_BINARY_DIR}/Analitza5ConfigVersion.cmake"
0067   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0068   COMPONENT Devel
0069 )
0070
0071 install(EXPORT AnalitzaTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE Analitza5Targets.cmake NAMESPACE KF5:: )
0072
0073 install(FILES
0074   ${CMAKE_CURRENT_BINARY_DIR}/analitza_version.h
0075   DESTINATION ${ANALITZA_INCLUDE_INSTALL_DIR} COMPONENT Devel
0076 )
0077
0078 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)