accessibility/kmousetool/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002
0003 # Release service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "1")
0007 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(kmousetool VERSION "${RELEASE_SERVICE_VERSION}")
0010
0011 set(QT_MIN_VERSION "5.15.2")
0012 set(KF_MIN_VERSION "5.92.0")
0013
0014 find_package (ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0015 set (CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(ECMInstallIcons)
0022 include(CheckIncludeFiles)
0023 include(FeatureSummary)
0024 include(KDEGitCommitHooks)
0025 include(KDEClangFormat)
0026 include(ECMDeprecationSettings)
0027 if (QT_MAJOR_VERSION STREQUAL "6")
0028     set(QT_REQUIRED_VERSION "6.4.0")
0029     set(KF_MIN_VERSION "5.240.0")
0030     set(KF_MAJOR_VERSION "6")
0031 else()
0032     set(KF_MAJOR_VERSION "5")
0033 endif()
0034 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0035 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0036
0037 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS Core Gui Widgets)
0038
0039 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED
0040     DBusAddons
0041     I18n
0042     IconThemes
0043     Notifications
0044     XmlGui
0045     WindowSystem
0046 )
0047 find_package(KF${KF_MAJOR_VERSION}DocTools ${KF_MIN_VERSION})
0048 set_package_properties(KF${KF_MAJOR_VERSION}DocTools PROPERTIES DESCRIPTION
0049     "Tools to generate documentation"
0050     TYPE OPTIONAL
0051 )
0052 find_package(Phonon4Qt${QT_MAJOR_VERSION} REQUIRED NO_MODULE)
0053
0054 find_package(X11 REQUIRED)
0055 if(NOT X11_Xt_FOUND)
0056     message(FATAL_ERROR "Cannot find X11 Xt component (libxt header file X11/Intrinsic.h)")
0057 endif(NOT X11_Xt_FOUND)
0058 if(NOT X11_XTest_FOUND)
0059     message(FATAL_ERROR "Cannot find X11 XTest component (libxcb-xtest header file X11/extensions/XTest.h)")
0060 endif(NOT X11_XTest_FOUND)
0061
0062 ecm_set_disabled_deprecation_versions(QT 6.4  KF 5.101.0)
0063
0064 add_subdirectory( kmousetool )
0065 ki18n_install(po)
0066 if(KF${KF_MAJOR_VERSION}DocTools_FOUND)
0067     kdoctools_install(po)
0068     add_subdirectory(doc)
0069 endif()
0070 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0071 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)